-
Notifications
You must be signed in to change notification settings - Fork 97
/
Copy pathMonadicSparseMatrixRecommender.m
3526 lines (2530 loc) · 131 KB
/
MonadicSparseMatrixRecommender.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Monadic Sparse Matrix Recommender Mathematica package
Copyright (C) 2018 Anton Antonov
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
Written by Anton Antonov,
antononcube @ posteo . net,
Windermere, Florida, USA.
*)
(*
Mathematica is (C) Copyright 1988-2018 Wolfram Research, Inc.
Protected by copyright law and international treaties.
Unauthorized reproduction or distribution subject to severe civil
and criminal penalties.
Mathematica is a registered trademark of Wolfram Research, Inc.
*)
(* :Title: MonadicSparseMatrixRecommender *)
(* :Context: MonadicSparseMatrixRecommender` *)
(* :Author: Anton Antonov *)
(* :Date: 2018-09-02 *)
(* :Package Version: 0.1 *)
(* :Mathematica Version: 11.3 *)
(* :Copyright: (c) 2018 antonov *)
(* :Keywords: *)
(* :Discussion:
*
* # In brief
*
* This package provides monadic implementation of a Item-Item Recommender (IIR) system.
* The IIR system is aimed at being fast and agile; see [1,2].
*
*
* # Discussion on the approach*
* ...
*
* # Usage example
* ...
*
* # Design considerations
*
* The monad commands are given "verb-like" names and appropriate synonyms are considered/added.
*
* It is an interesting question how to create the recommender.
* If we allow empty IIR monad structure creation SMRMonUnit[] then we have to be able
* to ingest matrices and datasets for the creation population of the IIR data structures.
*
*
* # Implementation considerations
*
* Note that the Sparse Matrix Recommender can be mapped into the Stream Blending Recommender. See [2].
*
* The easiest way to implement IIR is to reuse the Object-Oriented Programming (OOP) implementation [3].
* But OOP implementation [3] was developed before the introduction Association and the implementation of the
* packages SSparseMatrix.m, [4,5], and CrossTabulate.m, [6].
*
*
* # References
*
* [1] Anton Antonov, A fast and agile Item-Item Recommender system, (2011), Wolfram Technology Conference.
*
* [2] Anton Antonov, Mapping Sparse Matrix Recommender to Streams Blending Recommender, (2017), MathematicaForPrediction at GitHub.
*
* [3] Anton Antonov, Sparse Matrix Recommender Framework Mathematica package, (2014), MathematicaForPrediction at GitHub.
*
* [4] Anton Antonov, SSparseMatrix Mathematica unit tests, (2018), MathematicaForPrediction at GitHub.
* URL: https://github.com/antononcube/MathematicaForPrediction/blob/master/UnitTests/SSparseMatrix-tests.wlt
*
* [5] Anton Antonov, RSparseMatrix Mathematica package, (2015), MathematicaForPrediction at GitHub.
* URL: https://github.com/antononcube/MathematicaForPrediction/blob/master/Misc/RSparseMatrix.m
*
* [6] Anton Antonov, Cross tabulation implementation in Mathematica, (2017), MathematicaForPrediction at GitHub.
*
* *)
(*
* # TODOs
*
* 1. [X] [A] Implement tag-types re-weighting.
* 2. [X] [A] Implement tags re-weighting.
* 3. [ ] [B] Implement term weight functions application through association of tag-types.
* 4. [X] [A] Implement creation from long form dataset, and
* 5. [ ] [A] do corresponding refactoring.
* 6. [ ] [B] Refactor the codes of the term weight functions ("SMRMonApply*Function",).
*
* *)
(**************************************************************)
(* Importing packages (if needed) *)
(**************************************************************)
If[Length[DownValues[MathematicaForPredictionUtilities`RecordsSummary]] == 0,
Echo["MathematicaForPredictionUtilities.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MathematicaForPredictionUtilities.m"]
];
If[Length[DownValues[StateMonadCodeGenerator`GenerateStateMonadCode]] == 0,
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MonadicProgramming/StateMonadCodeGenerator.m"]
];
If[Length[DownValues[SSparseMatrix`ToSSparseMatrix]] == 0,
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/SSparseMatrix.m"]
];
If[Length[DownValues[DocumentTermMatrixConstruction`WeightTerms]] == 0,
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/DocumentTermMatrixConstruction.m"]
];
If[Length[DownValues[OutlierIdentifiers`OutlierIdentifier]] == 0,
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/OutlierIdentifiers.m"]
];
(**************************************************************)
(* Package definition *)
(**************************************************************)
BeginPackage["MonadicSparseMatrixRecommender`"];
$SMRMonFailure::usage = "Failure symbol of SMRMon.";
SMRMonScoredItemsQ::usage = "True if the argument is an association with item names or item indices as keys \
and numbers as values.";
SMRMonScoredTagsQ::usage = "True if the argument is an association with tags or tag indices as keys \
and numbers as values.";
SMRMonCreate::usage = "Creates the recommender structures from a transactions Dataset or an association of sparse matrices.";
SMRMonCreateFromWideForm::usage = "Creates the recommender structures from a transactions Dataset.";
SMRMonCreateFromLongForm::usage = "Creates the recommender structures from a long form Dataset -- \
each row is expected to have values corresponding to item ID, tag type, tag, weight.";
SMRMonApplyLocalWeightFunction::usage = "Applies a specified local weight function to the entries \
of the contingency matrix.";
SMRMonApplyGlobalWeightFunction::usage = "Applies a specified global weight function to the entries \
of the contingency matrix.";
SMRMonApplyNormalizationFunction::usage = "Applies a specified normalization function to the entries \
of the contingency matrix.";
SMRMonApplyTermWeightFunctions::usage = "Applies term weight functions to entries of the recommender matrix.";
SMRMonGetTopRecommendations::usage = "Recommends items based on a history or profile specification.";
SMRMonRecommend::usage = "Recommends items based on history.";
SMRMonRecommendByHistory::usage = "Recommends items based on history.";
SMRMonRecommendByProfile::usage = "Recommends items based on profile.";
SMRMonRecommendByCorrelation::usage = "Recommends items based on a correlation matrix. \
(The context value for the key \"timeSeriesMatrix\" should have the same dimensions and row names as the recommendation matrix.)";
SMRMonBatchRecommend::usage = "Recommends items using a SSparseMatrix object or a items specification.";
SMRMonToProfileVector::usage = "SMRMonToProfileVector[ prof : ( { _String ..} | Association[ (_Integer -> _?NumberQ) .. ] | Association[ (_String -> _?NumberQ) .. ] ) ] \
makes a profile vector from an argument that is a list of tags or an association of scored indices or scored tags.";
SMRMonFromProfileVector::usage = "Makes a profile association from a profile vector argument.";
SMRMonProfile::usage = "Computes profile based on history.";
SMRMonToItemsDataset::usage = "Converts a recommendations association into a Dataset object.";
SMRMonJoinAcross::usage = "Joins a recommendations association with a given Dataset object.";
SMRMonAnnexSubMatrix::usage = "Annexes matrices to the recommender. \
(Synonym of SMRMonAnnexSubMatrices.)";
SMRMonAnnexSubMatrices::usage = "Annexes matrices to the recommender.";
SMRMonJoin::usage = "Joins the recommender with another recommender. \
(By column-binding the corresponding tag-type sub-matrices.)";
SMRMonRowBind::usage = "Row-binds the recommender with another recommender. \
(By row-binding the corresponding tag-type sub-matrices.)";
SMRMonSetTagTypeWeights::usage = "Sets weights (significance factors) to the IIR tag types.";
SMRMonSetTagWeights::usage = "Sets weights (significance factors) to the IIR tags.";
SMRMonSetTimeSeriesMatrix::usage = "Sets a time series matrix to be used with SMRMonRecommendByCorrelation.";
SMRMonClassifyOriginal::usage = "Uses IIR as a classifier for specified label tag-type over a vector or a matrix.";
SMRMonClassify::usage = "Uses IIR as a classifier for specified label tag-type over a vector or a matrix.";
SMRMonSetClassificationParameters::usage = "Sets the parameters to be used by SMRMonClassifyOriginal.";
SMRMonProveByHistory::usage = "Computes proofs for recommendations using consumption history.";
SMRMonProveByProfile::usage = "Computes proofs for recommendations using consumption profile.";
SMRMonTakeMatrices::usage = "Gives an association with the tag (sparse) matrices.";
SMRMonTakeMatrix::usage = "Gives the recommendation matrix (SSparseMatrix).";
SMRMonTakeItemNames::usage = "Gives the item names. (Row names of the recommender matrix.)";
SMRMonTakeTags::usage = "Gives the tags. (Column names of the recommender matrix.)";
SMRMonTakeTagTypeWeights::usage = "Takes the tag-type weights.";
SMRMonTakeTagTypes::usage = "Takes the tag-types.";
SMRMonTakeMatrixDataset::usage = "Takes the Dataset object corresponding to the recommendation matrix.";
SMRMonGetTagTypeRanges::usage = "Gets the ranges of the tag types in the recommendation matrix.";
SMRMonProveByMetadata::usage = "Metadata proofs for a recommended item and a profile. \
(Tags from item's profile that are found in the given profile.)";
SMRMonProveByHistory::usage = "History proofs for a recommended item and scored history items.";
SMRMonEchoDataSummary::usage = "Echoes summary of the dataset.";
SMRMonGetProperty::usage = "Gets a recommender property.";
SMRMonGetMatrixProperty::usage = "Gets a recommender matrix property.";
SMRMonFilterByProfile::usage = "SMRMonFilterByProfile[ prof : ( { _String ..} | Association[ (_Integer -> _?NumberQ) .. ] | Association[ (_String -> _?NumberQ) .. ] ) ] \
finds the items that have the tags of the given profile. The scores are corresponding row sums.";
SMRMonFilterMatrix::usage = "SMRMonFilterMatrix[ prof : ( { _String ..} | Association[ (_Integer -> _?NumberQ) .. ] | Association[ (_String -> _?NumberQ) .. ] ) ] \
applies a profile filter to the rows of the recommendation matrix.";
SMRMonRetrieveByQueryElements::usage = "SMRMonRetrieveByQueryElements[should, must, mustNot] \
retrieves items according the retrieval query elements.";
SMRMonRemoveTagTypes::usage = "SMRMonRemoveTagTypes[ tagTypes : {_String..}] removes specified tag types.";
SMRMonComputeTopK::usage = "SMRMonComputeTopK[ testData_Association, ks:{_?IntegerQ..}, opts] computes the Top-K for specified data and K's.";
SMRMonToMetadataRecommender::usage = "SMRMonToMetadataRecommender[ tagTypeTo_String, opts] converts the recommender into a recommender for tagTypeTo tags.";
SMRMonImportRecommender::usage = "SMRMonImportRecommender[ dirName_String] imports a recommender \
using data files from the specified directory having the specified prefix and infix through the options \"Prefix\" and \"Infix\". \
This is a non-monadic function; can be used in place of SMRMonUnit[].";
Begin["`Private`"];
Needs["MathematicaForPredictionUtilities`"];
Needs["CrossTabulate`"];
Needs["StateMonadCodeGenerator`"];
Needs["SSparseMatrix`"];
Needs["DocumentTermMatrixConstruction`"];
Needs["OutlierIdentifiers`"];
(**************************************************************)
(* Generation *)
(**************************************************************)
(* Generate base functions of SMRMon monad (through StMon.) *)
GenerateStateMonadCode[ "MonadicSparseMatrixRecommender`SMRMon", "FailureSymbol" -> $SMRMonFailure, "StringContextNames" -> False ];
GenerateMonadAccessors[
"MonadicSparseMatrixRecommender`SMRMon",
{"data", "M", "M01", "matrices", "itemNames", "tags", "tagTypeWeights", "timeSeriesMatrix" },
"FailureSymbol" -> $SMRMonFailure ];
GenerateMonadAccessors[
"MonadicSparseMatrixRecommender`SMRMon",
{"M", "M01"},
"DecapitalizeElementName" -> False,
"FailureSymbol" -> $SMRMonFailure ];
(**************************************************************)
(* Setters / getters *)
(**************************************************************)
(* Here we can/have to have a correctness check. It is one of the advantages to SSparseMatrix. *)
(*SMRMonSetItemNames[names_][xs_, context_Association] :=*)
(*SMRMonUnit[ xs, Join[context, <|"itemNames"->names|>] ];*)
Clear[SMRMonTakeTagTypes];
SMRMonTakeTagTypes[$SMRMonFailure] := $SMRMonFailure;
SMRMonTakeTagTypes[][$SMRMonFailure] := $SMRMonFailure;
SMRMonTakeTagTypes[xs_, context_Association] := SMRMonTakeTagTypes[][xs, context];
SMRMonTakeTagTypes[][xs_, context_Association] := Keys[Lookup[context, "matrices"]];
SMRMonTakeTagTypes[__][___] := $SMRMonFailure;
Clear[SMRMonTakeMatrix];
SMRMonTakeMatrix = SMRMonTakeM;
Clear[SMRMonTakeMatrixDataset];
SMRMonTakeMatrixDataset[$SMRMonFailure] := $SMRMonFailure;
SMRMonTakeMatrixDataset[][$SMRMonFailure] := $SMRMonFailure;
SMRMonTakeMatrixDataset[xs_, context_] := SMRMonTakeMatrixDataset[][xs, context];
SMRMonTakeMatrixDataset[][xs_, context_Association] :=
Block[{smats},
smats = SMRMonTakeMatrices[][xs, context];
If[ TrueQ[smats === $SMRMonFailure],
$SMRMonFailure,
(*ELSE*)
smats =
Map[
Dataset[SSparseMatrixToTriplets[#]][All, AssociationThread[{"Item", "Tag", "Weight"} -> #]&]&,
smats
];
smats = KeyValueMap[ Function[{k, v}, v[All, Join[#, <|"TagType" -> k|>]&]], smats];
(Join @@ smats)[All, {"Item", "TagType", "Tag", "Weight"}]
]
];
SMRMonTakeMatrixDataset[__][___] := $SMRMonFailure;
(**************************************************************)
(* Predicates *)
(**************************************************************)
Clear[ScoredItemIndexesQ];
ScoredItemIndexesQ[recs_Association, context_Association] :=
If[ KeyExistsQ[context, "M"],
AssociationQ[recs] &&
VectorQ[Values[recs], NumberQ] &&
Apply[And, Map[TrueQ[0 < # <= RowsCount[context["M"]]]&, Keys[recs]] ],
True,
(*ELSE*)
AssociationQ[recs] && VectorQ[Values[recs], NumberQ]
];
ScoredItemIndexesQ[___] := False;
Clear[SMRMonScoredItemsQ];
SMRMonScoredItemsQ[$SMRMonFailure] := $SMRMonFailure;
SMRMonScoredItemsQ[xs_, context_Association] := SMRMonScoredItemsQ[xs][xs, context];
SMRMonScoredItemsQ[][xs_, context_Association] := SMRMonScoredItemsQ[xs][xs, context];
SMRMonScoredItemsQ[recs_Association][xs_, context_Association] :=
Block[{res},
res =
If[ KeyExistsQ[context, "itemNames"],
AssociationQ[recs] &&
VectorQ[Values[recs], NumberQ] &&
( VectorQ[context["itemNames"] /@ Keys[recs], IntegerQ] ||
1 <= Min[Keys[recs]] && Max[Keys[recs]] <= Length[context["itemNames"]]
),
(*ELSE*)
AssociationQ[recs] && VectorQ[Values[recs], NumberQ]
];
SMRMonUnit[res, context]
];
SMRMonScoredItemsQ[__][___] := $SMRMonFailure;
Clear[SMRMonScoredTagsQ];
SMRMonScoredTagsQ[$SMRMonFailure] := $SMRMonFailure;
SMRMonScoredTagsQ[xs_, context_Association] := SMRMonScoredTagsQ[xs][xs, context];
SMRMonScoredTagsQ[][xs_, context_Association] := SMRMonScoredTagsQ[xs][xs, context];
SMRMonScoredTagsQ[recs_Association][xs_, context_Association] :=
Block[{res},
res =
If[ KeyExistsQ[context, "tags"],
AssociationQ[recs] &&
VectorQ[Values[recs], NumberQ] &&
( VectorQ[context["tags"] /@ Keys[recs], IntegerQ] ||
1 <= Min[Keys[recs]] && Max[Keys[recs]] <= Length[context["tags"]]
),
(*ELSE*)
AssociationQ[recs] && VectorQ[Values[recs], NumberQ]
];
SMRMonUnit[res, context]
];
SMRMonScoredTagsQ[__][___] := $SMRMonFailure;
(* Private function. *)
Clear[ScoredItemsQ];
ScoredItemsQ[recs_Association, context_Association] :=
Block[{},
TrueQ[ Fold[ SMRMonBind, SMRMonUnit[None, context], { SMRMonScoredItemsQ[recs], SMRMonTakeValue}] ]
];
ScoredItemsQ[_, context_Association] := False;
ScoredItemsQ[___] := (Echo["Wrong signature!", "ScoredItemsQ:"]; False);
(* Private function. *)
Clear[ScoredTagsQ];
ScoredTagsQ[prof_Association, context_Association] :=
Block[{},
TrueQ[ Fold[ SMRMonBind, SMRMonUnit[None, context], { SMRMonScoredTagsQ[prof], SMRMonTakeValue}] ]
];
ScoredTagsQ[_, context_Association] := False;
ScoredTagsQ[___] := (Echo["Wrong signature!", "ScoredTagsQ:"]; False);
(* Private function. *)
Clear[DatasetWithScoredItemsQ];
DatasetWithScoredItemsQ[recs_Dataset, context_Association] :=
Block[{colNames = Normal @ Keys @ recs[[1]] },
If[ Length[ Intersection[ colNames, {"Item", "Score"} ] ] < 2,
False,
ScoredItemsQ[ AssociationThread[ Normal[ recs[All, "Item"] ], Normal[ recs[All, "Score"] ] ], context ]
]
];
DatasetWithScoredItemsQ[_, context_Association] := False;
DatasetWithScoredItemsQ[___] := (Echo["Wrong signature!", "DatasetWithScoredItemsQ:"]; False);
(**************************************************************)
(* Creation *)
(**************************************************************)
(* This can be a function MathematicaForPredictionUtilities.m . *)
Clear[NumericalColumns];
NumericalColumns[ds_Dataset] :=
Block[{aNumColsQ},
aNumColsQ =
Normal@ds[
Transpose /*
Query[All, VectorQ[DeleteMissing[#], NumericQ] &]];
Keys[Pick[aNumColsQ, Values[aNumColsQ]]]
];
(*
I am trying to avoid the package DateReshape.m here. Using ToLongForm from that package we can do:
ToSSparseMatrix@
CrossTabulate[ToLongForm[ds[All, {idColumnName, varColumnName}], {idColumnName}, {varColumnName}]]
*)
Clear[NumericalColumnToSSparseMatrix];
NumericalColumnToSSparseMatrix[dsArg_Dataset, idColumnName_, varColumnName_] :=
Block[{ds = dsArg},
ds = dsArg[All, {idColumnName, varColumnName}][All, Join[#, <|"Variable" -> varColumnName|>]&];
ds = Query[ReplaceAll[Missing[] -> 0], All][ds];
ToSSparseMatrix @ CrossTabulate[ ds[All, {idColumnName, "Variable", varColumnName}], "Sparse" -> True ]
];
Clear[SMRMonCreate];
(*SMRMonCreate::rneq = "The row names of SSparseMatrix objects are not the same."*)
(*SMRMonCreate::niid = "The specified item variable name is not one of the column names of the dataset."*)
SyntaxInformation[SMRMonCreate] = { "ArgumentsPattern" -> { _., _., OptionsPattern[] } };
Options[SMRMonCreate] =
{
"AddTagTypesToColumnNames" -> False,
"TagValueSeparator" -> ".",
"NumericalColumnsAsCategorical" -> False,
"MissingValuesPattern" -> (None | "None" | Missing[___])
};
SMRMonCreate[$SMRMonFailure] := $SMRMonFailure;
SMRMonCreate[xs_, context_Association] := SMRMonCreate[][xs, context];
SMRMonCreate[][xs_, context_Association] := SMRMonCreate[Options[SMRMonCreate]][xs, context];
SMRMonCreate[ opts : OptionsPattern[] ][xs_, context_Association] :=
Which[
MatrixQ[xs, NumberQ],
SMRMonCreate[ xs, opts ][xs, context],
MatchQ[xs, _SSparseMatrix] || MatchQ[xs, Association[ (_ -> _SSparseMatrix) ..] ],
SMRMonCreate[ xs, opts ][xs, context],
AssociationQ[xs] && KeyExistsQ[xs, "data"] && KeyExistsQ[xs, "idColumnName"],
SMRMonCreate[ xs["data"], xs["idColumnName"], opts ][xs, context],
AssociationQ[xs] && KeyExistsQ[xs, "data"] && KeyExistsQ[xs, "itemColumnName"],
SMRMonCreate[ xs["data"], xs["itemColumnName"], opts ][xs, context],
AssociationQ[xs] && KeyExistsQ[xs, "data"],
SMRMonCreate[ xs["data"], First @ Normal @ Keys @ xs["data"][[1]], opts ][xs, context],
TrueQ[ Head[xs] === Dataset ],
SMRMonCreate[ xs, First @ Normal @ Keys @ xs[[1]], opts ][xs, context],
True,
SMRMonCreate["Fail"][xs, context]
];
SMRMonCreate[ mat_?MatrixQ, opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{smat},
smat = ToSSparseMatrix[SparseArray[mat], "RowNames" -> ToString /@ Range[Length[mat]]];
SMRMonCreate[ <| "anonymous" -> smat |>, opts][xs, context]
] /; MatrixQ[ mat, NumberQ ];
SMRMonCreate[ smat_SSparseMatrix, opts : OptionsPattern[] ][xs_, context_Association] :=
SMRMonCreate[ <| "anonymous" -> smat |>, opts][xs, context];
SMRMonCreate[smatsArg : Association[ (_ -> _SSparseMatrix) ..], opts : OptionsPattern[]][xs_, context_Association] :=
Block[{smats = smatsArg, addTagTypesToColumnNamesQ, tagValueSeparator, tagTypeNames, rowNames, columnNames, lsCommonColumnNames, splicedMat},
addTagTypesToColumnNamesQ = TrueQ[OptionValue[SMRMonCreate, "AddTagTypesToColumnNames"]];
tagValueSeparator = ToString[OptionValue[SMRMonCreate, "TagValueSeparator"]];
tagTypeNames = Keys[smats];
rowNames = Map[RowNames, smats];
If[ !(Equal @@ rowNames),
(* Echo["The row names of the SSparseMatrix objects are expected to be the same.", "SMRMonCreate:"]; *)
rowNames = Union[Flatten[Values[rowNames]]];
smats = Map[ ImposeRowNames[ #, rowNames ]&, smats];
];
If[addTagTypesToColumnNamesQ,
smats =
Association @
KeyValueMap[Function[{k, mat},
k -> ToSSparseMatrix[mat,
"ColumnNames" -> Map[ k <> tagValueSeparator <> #&, ColumnNames[mat] ],
"RowNames" -> RowNames[mat]
]], smats]
];
lsCommonColumnNames =
Association @ Flatten @
Map[
# -> Length[Intersection[ColumnNames@smats[#[[1]]], ColumnNames@smats[#[[2]]]]]&,
Flatten[ Table[ Keys[smats][[{k1, k2}]], {k1, 1, Length[smats]}, {k2, k1 + 1, Length[smats]}], 1]
];
lsCommonColumnNames = Select[ KeySelect[ lsCommonColumnNames, Not[Equal @@ #]&], # > 0 &];
If[ Length[lsCommonColumnNames] > 0,
Echo[
"Some of the creation sub-matrices have common column names, therefore the columns were renamed." <>
" Sub-matrices with common column names: " <>
ToString[lsCommonColumnNames] <>
" .",
"SMRMonCreate:" ];
];
splicedMat = ColumnBind[Values[smats]];
rowNames = RowNames[splicedMat];
columnNames = ColumnNames[splicedMat];
SMRMonUnit[
xs,
Join[
context,
<|
"itemNames" -> AssociationThread[rowNames -> Range[Length[rowNames]]],
"tags" -> AssociationThread[columnNames -> Range[Length[columnNames]]],
"tagTypeWeights" -> AssociationThread[Keys[smats], ConstantArray[1, Length[smats]]],
"matrices" -> smats,
"M01" -> splicedMat,
"M" -> splicedMat
|>
]
]
];
SMRMonCreate[ds_Dataset, opts : OptionsPattern[]][xs_, context_Association] :=
Block[{itemVarName, keys},
keys = Normal @ Keys @ ds[[1]];
Which[
MemberQ[ ToLowerCase[keys], "id" ],
itemVarName = keys[[ First @ Flatten @ Position[ ToLowerCase[keys], "id" ] ]],
MemberQ[ ToLowerCase[keys], "item" ],
itemVarName = keys[[ First @ Flatten @ Position[ ToLowerCase[keys], "item" ] ]],
True,
itemVarName = First @ Normal @ Keys @ ds[[1]];
];
Echo[ "Heuristically picking the ID column to be \"" <> itemVarName <> "\".", "SMRMonCreate:" ];
SMRMonCreate[ds, itemVarName, opts][xs, context]
];
SMRMonCreate[ds_Dataset, itemVarName_String, opts : OptionsPattern[]][xs_, context_Association] :=
Block[{ },
SMRMonCreateFromWideForm[ds, itemVarName, opts][xs, context]
];
SMRMonCreate[ds_Dataset, { itemColumnName_String, tagTypeColumnName_String, tagColumnName_String, weightColumnName_String }, opts : OptionsPattern[]][xs_, context_Association] :=
Block[{ },
SMRMonCreateFromLongForm[
ds,
{ itemColumnName, tagTypeColumnName, tagColumnName, weightColumnName },
FilterRules[ opts, Options[SMRMonCreateFromLongForm] ]
][xs, context]
];
SMRMonCreate[___][__] :=
Block[{},
Echo[
"The first argument is expected to be a Dataset, a matrix, a SSparseMatrix object, or an association of SSparseMatrix objects. " <>
"If the first argument is a Dataset a second argument is expected. " <>
"That second argument should be an item ID column name in that Dataset (wide form) " <>
"or a list of four strings specifying the column names that correspond to item ID, tag type, tag, weight. " <>
"If no arguments are given the pipeline value is used.",
"SMRMonCreate:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonCreateFromWideForm *)
(**************************************************************)
Clear[SMRMonCreateFromWideForm];
SyntaxInformation[SMRMonCreateFromWideForm] = { "ArgumentsPattern" -> { _, _, OptionsPattern[] } };
Options[SMRMonCreateFromWideForm] =
{
"AddTagTypesToColumnNames" -> False,
"TagValueSeparator" -> ".",
"NumericalColumnsAsCategorical" -> False,
"MissingValuesPattern" -> (None | "None" | Missing[___])
};
SMRMonCreateFromWideForm[$SMRMonFailure] := $SMRMonFailure;
SMRMonCreateFromWideForm[xs_, context_Association] := $SMRMonFailure;
SMRMonCreateFromWideForm[][xs_, context_Association] := $SMRMonFailure;
SMRMonCreateFromWideForm[ds_Dataset, itemVarName_String, opts : OptionsPattern[]][xs_, context_Association] :=
Block[{ ncol, tagTypeNames, smats, idPos, idName, numCols, ds2, rowNames, allRowNames,
numericalColumnsAsCategoricalQ, missingValuesPattern},
numericalColumnsAsCategoricalQ = TrueQ[OptionValue[SMRMonCreateFromWideForm, "NumericalColumnsAsCategorical"]];
missingValuesPattern = OptionValue[SMRMonCreateFromWideForm, "MissingValuesPattern"];
ncol = Dimensions[ds][[2]];
tagTypeNames = Normal[Keys[ds[1]]];
idPos = Flatten[Position[tagTypeNames, itemVarName]];
If[ Length[idPos] == 0,
Echo["The specified item variable name is not one of the column names of the dataset.", "SMRMonCreate:"];
Return[$Failed]
];
idPos = First[idPos];
idName = tagTypeNames[[idPos]];
If[ numericalColumnsAsCategoricalQ,
(* This is intentionally separated from the 'else' code in order to avoid the redundant call to NumericalColumns. *)
smats = Table[ v -> ToSSparseMatrix[ CrossTabulate[ds[All, {idName, v}], "Sparse" -> True ]], {v, Complement[ tagTypeNames, {idName} ]}],
(*ELSE*)
numCols = NumericalColumns[ds];
smats =
Table[
If[ MemberQ[numCols, v],
v -> NumericalColumnToSSparseMatrix[ds, idName, v],
(*ELSE*)
ds2 = ds[All, {idName, v}];
ds2 = ds2[ Select[ FreeQ[#, missingValuesPattern]& ] ];
v -> ToSSparseMatrix[ CrossTabulate[ds2, "Sparse" -> True] ]
], {v, Complement[ tagTypeNames, {idName} ]}];
];
smats = Association[smats];
SMRMonCreate[smats, opts][xs, Join[context, <|"data" -> ds|>]]
];
SMRMonCreateFromWideForm[___][__] :=
Block[{},
Echo[
"The first argument is expected to be a Dataset object. " <>
"The second argument is expected to be a column name in that Dataset.",
"SMRMonCreateFromWideForm:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonCreateFromLongForm *)
(**************************************************************)
Clear[SMRMonCreateFromLongForm];
SyntaxInformation[SMRMonCreateFromLongForm] = { "ArgumentsPattern" -> { _, ___, OptionsPattern[] } };
Options[SMRMonCreateFromLongForm] =
{
"AddTagTypesToColumnNames" -> True,
"TagValueSeparator" -> ":",
"MissingValuesPattern" -> (None | "None" | Missing[___])
};
SMRMonCreateFromLongForm[$SMRMonFailure] := $SMRMonFailure;
SMRMonCreateFromLongForm[xs_, context_Association] := $SMRMonFailure;
SMRMonCreateFromLongForm[][xs_, context_Association] := $SMRMonFailure;
SMRMonCreateFromLongForm[ds_Dataset, opts : OptionsPattern[]][xs_, context_Association] :=
Block[{defaultColumnNames = { "Item", "TagType", "Tag", "Weight" } },
Echo["Assuming the long form column names are " <> ToString[defaultColumnNames] <> "."];
SMRMonCreateFromLongForm[ds, defaultColumnNames, opts ][xs, context]
];
SMRMonCreateFromLongForm[ds_Dataset, { itemColumnName_String, tagTypeColumnName_String, tagColumnName_String, weightColumnName_String }, opts : OptionsPattern[]][xs_, context_Association] :=
Block[{ tagTypeNames, smats,
addTagTypesToColumnNamesQ, tagValueSeparator, missingValuesPattern},
addTagTypesToColumnNamesQ = TrueQ[OptionValue[SMRMonCreateFromLongForm, "AddTagTypesToColumnNames"]];
tagValueSeparator = ToString[OptionValue[SMRMonCreateFromLongForm, "TagValueSeparator"]];
missingValuesPattern = OptionValue[SMRMonCreateFromLongForm, "MissingValuesPattern"];
If[ Length[ Intersection[ Normal @ Keys @ ds[[1]], {itemColumnName, tagTypeColumnName, tagColumnName, weightColumnName} ] ] != 4,
Echo[
"Not all of the specified column names are column names in the dataset. " <>
"The expected dataset column names are:" <> ToString[ {itemColumnName, tagTypeColumnName, tagColumnName, weightColumnName} ] <> ".",
"SMRMonCreateFromLongForm:"];
Return[$Failed]
];
tagTypeNames = Union[ Normal[ ds[All, tagTypeColumnName] ] ];
smats = Association @ Map[Function[{tt}, tt -> ToSSparseMatrix @ CrossTabulate[ ds[ Select[#TagType == tt &], {itemColumnName, tagColumnName, weightColumnName}], "Sparse" -> True] ], tagTypeNames];
If[addTagTypesToColumnNamesQ,
smats =
Association @
KeyValueMap[Function[{k, mat},
k -> ToSSparseMatrix[mat,
"ColumnNames" -> Map[ k <> tagValueSeparator <> #&, ColumnNames[mat] ],
"RowNames" -> RowNames[mat]
]], smats]
];
SMRMonCreate[smats][xs, context]
];
SMRMonCreateFromLongForm[___][__] :=
Block[{},
Echo[
"The first argument is expected to be a Dataset object. " <>
"The optional second argument is expected to be a list four strings : " <>
"{ itemColumnName_String, tagTypeColumnName_String, tagColumnName_String, weightColumnName_String } .",
"SMRMonCreateFromLongForm:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonGetTagTypeRanges *)
(**************************************************************)
Clear[SMRMonGetTagTypeRanges];
SyntaxInformation[SMRMonGetTagTypeRanges] = { "ArgumentsPattern" -> {} };
SMRMonGetTagTypeRanges[$SMRMonFailure] := $SMRMonFailure;
SMRMonGetTagTypeRanges[][$SMRMonFailure] := $SMRMonFailure;
SMRMonGetTagTypeRanges[xs_, context_Association] := SMRMonGetTagTypeRanges[][xs, context];
SMRMonGetTagTypeRanges[][xs_, context_Association] :=
Block[{lsNCols, aTagTypeRanges},
lsNCols = Map[ColumnsCount, SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeMatrices] ];
aTagTypeRanges = AssociationThread[Keys[lsNCols], Transpose[{Prepend[Most[Accumulate[Values@lsNCols]], 0] + 1, Accumulate[Values@lsNCols]}]];
SMRMonUnit[ aTagTypeRanges, context]
];
SMRMonGetTagTypeRanges[___][__] :=
Block[{},
Echo["No arguments are expected.", "SMRMonGetTagTypeRanges:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonEchoDataSummary *)
(**************************************************************)
Clear[SMRMonEchoDataSummary];
SyntaxInformation[SMRMonEchoDataSummary] = { "ArgumentsPattern" -> {} };
SMRMonEchoDataSummary[$SMRMonFailure] := $SMRMonFailure;
SMRMonEchoDataSummary[][$SMRMonFailure] := $SMRMonFailure;
SMRMonEchoDataSummary[xs_, context_Association] := SMRMonEchoDataSummary[][xs, context];
SMRMonEchoDataSummary[][xs_, context_Association] :=
Block[{},
If[ TrueQ[ SMRMonTakeData[xs, context] === $SMRMonFailure ],
$SMRMonFailure,
SMRMonBind[ SMRMonUnit[xs, context], SMRMonEchoFunctionContext[ "data summary:", RecordsSummary[#data] & ] ]
]
];
SMRMonEchoDataSummary[___][__] :=
Block[{},
Echo["No arguments are expected.", "SMRMonEchoDataSummary:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonGetProperty *)
(**************************************************************)
Clear[SMRMonGetProperty];
SyntaxInformation[SMRMonGetProperty] = { "ArgumentsPattern" -> {_} };
SMRMonGetProperty[$SMRMonFailure] := $SMRMonFailure;
SMRMonGetProperty[][$SMRMonFailure] := $SMRMonFailure;
SMRMonGetProperty[xs_, context_Association] := SMRMonGetProperty[None][xs, context];
SMRMonGetProperty[ property_String ][xs_, context_Association] :=
Block[{res, cms},
res =
Which[
ToLowerCase[property] == ToLowerCase["TagTypes"],
SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeTagTypes],
ToLowerCase[property] == ToLowerCase["TagTypeRanges"],
cms = ColumnsCount /@ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeMatrices];
AssociationThread[ Keys[cms], Rest[ FoldList[{#1[[2]] + 1, #1[[2]] + #2} &, {0, 0}, Values[cms]] ] ],
ToLowerCase[property] == ToLowerCase["ItemColumnName"],
SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeItemColumnName],
MemberQ[ ToLowerCase[ {"Matrix", "M"} ], ToLowerCase[property] ],
SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM],
MemberQ[ ToLowerCase[ {"IncidenceMatrix", "M01"} ], ToLowerCase[property] ],
SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM01],
MemberQ[ ToLowerCase[ {"Matrices", "SubMatrices", "SubMatrixes", "ContingencyMatrices", "ContingencyMatrixes"} ], ToLowerCase[property] ],
SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeMatrices],
ToLowerCase[property] == ToLowerCase["Properties"],
{ "Matrix", "IncidenceMatrix", "SubMatrices", "Properties" },
True,
Echo[ "Unknown property specification.", "SMRMonGetProperty:"];
Return[$SMRMonFailure]
];
SMRMonUnit[ res, context ]
];
SMRMonGetProperty[___][__] :=
Block[{},
Echo["One string argument is expected.", "SMRMonGetProperty:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonGetMatrixProperty *)
(**************************************************************)
Clear[SMRMonGetMatrixProperty];
SyntaxInformation[SMRMonGetMatrixProperty] = { "ArgumentsPattern" -> {_} };
SMRMonGetMatrixProperty[$SMRMonFailure] := $SMRMonFailure;
SMRMonGetMatrixProperty[][$SMRMonFailure] := $SMRMonFailure;
SMRMonGetMatrixProperty[xs_, context_Association] := SMRMonGetMatrixProperty[None][xs, context];
SMRMonGetMatrixProperty[ property_String ][xs_, context_Association] :=
Block[{res},
res =
Which[
MemberQ[ ToLowerCase[ {"Tags", "Columns"} ], ToLowerCase[property] ],
ColumnNames[ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM] ],
ToLowerCase[property] == ToLowerCase["Rows"],
RowNames[ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM] ],
MemberQ[ ToLowerCase[ {"NumberOfColumns", "ColumnsCount"} ], ToLowerCase[property] ],
ColumnsCount[ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM] ],
MemberQ[ ToLowerCase[ {"NumberOfRows", "ColumnsRows"} ], ToLowerCase[property] ],
RowsCount[ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM] ],
MemberQ[ ToLowerCase[ {"Dimensions", "Dim"} ], ToLowerCase[property] ],
Dimensions[ SparseArray[ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM] ] ],
ToLowerCase[property] == ToLowerCase["Density"],
SparseArray[ SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeM] ]["Density"],
MemberQ[ ToLowerCase[ {"TagTypeWeights", "TagTypeSignificanceFactors"} ], ToLowerCase[property] ],
SMRMonBind[ SMRMonUnit[xs, context], SMRMonTakeTagTypeWeights],
ToLowerCase[property] == ToLowerCase["Properties"],
{ "Tags", "Columns", "Rows",
"NumberOfColumns", "NumberOfRows",
"Dim", "Dimensions", "Density",
"TagTypeWeights", "TagTypeSignificanceFactors",
"Properties" },
True,
Echo[ "Unknown property specification.", "SMRMonGetMatrixProperty:"];
Return[$SMRMonFailure]
];
SMRMonUnit[ res, context ]
];
SMRMonGetMatrixProperty[___][__] :=
Block[{},
Echo["One string argument is expected.", "SMRMonGetMatrixProperty:"];
$SMRMonFailure
];
(**************************************************************)
(* SMRMonFilterByProfile *)
(**************************************************************)
Clear[SMRMonFilterByProfile];
SyntaxInformation[SMRMonFilterByProfile] = { "ArgumentsPattern" -> {_, OptionsPattern[]} };
Options[SMRMonFilterByProfile] = { "Type" -> "Intersection" };
SMRMonFilterByProfile[$SMRMonFailure] := $SMRMonFailure;
SMRMonFilterByProfile[][$SMRMonFailure] := $SMRMonFailure;
SMRMonFilterByProfile[xs_, context_Association] := SMRMonFilterByProfile[None][xs, context];
SMRMonFilterByProfile[ profile_Association, opts : OptionsPattern[] ][xs_, context_Association] :=
SMRMonFilterByProfile[ Keys[profile], opts][xs, context];
SMRMonFilterByProfile[ profile_String, opts : OptionsPattern[] ][xs_, context_Association] :=
SMRMonFilterByProfile[ {profile}, opts][xs, context];
SMRMonFilterByProfile[ profile : {_String ..}, opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{ filterType, pvec, svec, rowInds, res },
filterType = OptionValue[ SMRMonFilterByProfile, "Type" ];
pvec = Fold[ SMRMonBind, SMRMonUnit[xs, context], { SMRMonToProfileVector[profile], SMRMonTakeValue } ];
If[ TrueQ[ pvec === $SMRMonFailure ],
Echo["Cannot make a profile vector.", "SMRMonFilterByProfile:"];
Return[$SMRMonFailure]
];
pvec = Unitize[pvec];