-
Notifications
You must be signed in to change notification settings - Fork 97
/
Copy pathMonadicQuantileRegression.m
1992 lines (1380 loc) · 69.7 KB
/
MonadicQuantileRegression.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Monadic Quantile Regression Mathematica package
Copyright (C) 2018 Anton Antonov
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
Written by Anton Antonov,
ʇǝu˙oǝʇsod@ǝqnɔuouoʇuɐ,
Windermere, Florida, USA.
*)
(*
Mathematica is (C) Copyright 1988-2018 Wolfram Research, Inc.
Protected by copyright law and international treaties.
Unauthorized reproduction or distribution subject to severe civil
and criminal penalties.
Mathematica is a registered trademark of Wolfram Research, Inc.
*)
(* :Title: MonadicQuantileRegression *)
(* :Context: MonadicQuantileRegression` *)
(* :Author: Anton Antonov *)
(* :Date: 2018-06-03 *)
(* :Package Version: 1.0 *)
(* :Mathematica Version: 11.3 *)
(* :Copyright: (c) 2018 Anton Antonov *)
(* :Keywords: quantile regression, monad, workflow *)
(* :Discussion:
# In brief
This package provides a software monad implementation for Quantile regression workflows.
The functionalities of the package are described in [1,2].
# Usage example
sqPoints = Table[{x, Sqrt[x]}, {x, 1/2, 8, 0.1}];
ListPlot[sqPoints]
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MonadicProgramming/MonadicQuantileRegression.m"]
p =
QRMonUnit[sqPoints]⟹
QRMonQuantileRegressionFit[20, 0.5]⟹
QRMonPlot[]⟹
QRMonErrorPlots⟹
QRMonErrors⟹
QRMonEchoFunctionValue["Relative errors summary:", RecordsSummary /@ # &];
qFunc = (p⟹QRMonTakeRegressionFunctions)[0.5];
Simplify[qFunc[x]]
(* 27.05 - 245.125 x + 1011.11 x^2 - 2479.16 x^3 + 4080.66 x^4 - 4812.07 x^5 +
4233.13 x^6 - 2853.77 x^7 + 1501.85 x^8 - 624.791 x^9 + 207.112 x^10 -
54.9287 x^11 + 11.6595 x^12 - 1.97386 x^13 + 0.264376 x^14 -
0.0276295 x^15 + 0.00220351 x^16 - 0.000129425 x^17 + 5.27363*10^-6 x^18 -
1.3307*10^-7 x^19 + 1.56554*10^-9 x^20 *)
Instead of doing the fit with Chebyshev polynomials basis through QRMonQuantileRegressionFit one can use
a B-spline basis with QRMonQuantileRegression; see [1,2] for details.
# References
[1] Anton Antonov, "A monad for Quantile Regression workflows", (2018), MathematicaForPrediction at WordPress.
URL: https://mathematicaforprediction.wordpress.com/2018/08/01/a-monad-for-quantile-regression-workflows/ .
[2] Anton Antonov, "A monad for Quantile Regression workflows", (2018), MathematicaForPrediction at GitHub.
URL: https://github.com/antononcube/MathematicaForPrediction/blob/master/MarkdownDocuments/A-monad-for-Quantile-Regression-workflows.md .
Anton Antonov
June-July 2018
Windermere, Florida, USA
*)
(**************************************************************)
(* Importing packages (if needed) *)
(**************************************************************)
If[Length[DownValues[MathematicaForPredictionUtilities`RecordsSummary]] == 0,
Echo["MathematicaForPredictionUtilities.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MathematicaForPredictionUtilities.m"]
];
If[Length[DownValues[StateMonadCodeGenerator`GenerateStateMonadCode]] == 0,
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MonadicProgramming/StateMonadCodeGenerator.m"]
];
If[Length[DownValues[QuantileRegression`QuantileRegression]] == 0,
Echo["QuantileRegression.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/QuantileRegression.m"]
];
If[Length[DownValues[OutlierIdentifiers`OutlierPosition]] == 0,
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/OutlierIdentifiers.m"]
];
(**************************************************************)
(* Package definition *)
(**************************************************************)
BeginPackage["MonadicQuantileRegression`"];
$QRMonFailure::usage = "Failure symbol for the monad QRMon.";
QRMonGetData::usage = "Get time series path data.";
QRMonTakeData::usage = "Takes the time series path data.";
QRMonEchoDataSummary::usage = "QRMonEchoDataSummary[] echoes a summary of the data.";
QRMonDeleteMissing::usage = "QRMonDeleteMissing[] deletes records with missing data.";
QRMonRescale::usage = "QRMonRescale[Axes->{_,_}] rescales the data.";
QRMonLeastSquaresFit::usage = "QRMonLeastSquaresFit[ funcs : ( _List | _Integer ) ] does a Linear regression fit \
for the data in the pipeline or the context using specified functions to fit.";
QRMonFit::usage = "Same as QRMonLinearRegressionFit.";
QRMonQuantileRegression::usage = "QRMonQuantileRegression[knots: ( _Integer | _?VectorQ ), probs_?VectorQ, opts___] \
does Quantile Regression for the data in the pipeline or the context.";
QRMonRegression::usage = "Same as QRMonQuantileRegression.";
QRMonQuantileRegressionFit::usage = "QRMonLinearRegressionFit[ funcs : ( _List | _Integer), probs_?VectorQ ] does a \
Quantile regression fit using specified functions to fit and probabilities. An integer funcs specifies \
a ChebyshevT polynomials basis.";
QRMonRegressionFit::usage = "Same as QRMonQuantileRegressionFit.";
QRMonNetRegression::usage = "Regression using a neural network.";
QRMonEvaluate::usage = "QRMonEvaluate[points_?VectorQ] evaluates the regression functions over a number \
or a list of numbers.";
QRMonPlot::usage = "QRMonPlot[opts___] plots the data points or the data points together with the found regression curves.";
QRMonDateListPlot::usage = "QRMonDateListPlot[opts___] plots the data points or the data points together with the found regression curves.";
QRMonErrors::usage = "QRMonErrors[opts___] finds relative or absolute approximation errors for each regression quantile.";
QRMonErrorPlots::usage = "QRMonErrorPlots[opts___] plots relative approximation errors for each regression quantile.";
QRMonConditionalCDF::usage = "QRMonConditionalCDF[points_?VectorQ] finds conditional CDF approximations for specified points.";
QRMonConditionalCDFPlot::usage = "QRMonConditionalCDFPlot[ points_., opts] plots approximations of conditional CDF. \
If the points are not specified the pipeline value is used if it is an association of CDF's.";
QRMonOutliers::usage = "QRMonOutliers[] finds the outliers in the data.";
QRMonOutliersPlot::usage = "QRMonOutliersPlot[opts___] plots the outliers in the data. \
Finds them first if not already in the context.";
QRMonPickPathPoints::usage = "QRMonPickPathPoints[th_?NumberQ, opts___] picks points close to the regression functions \
using a specified threshold. \
With the option setting \"PickAboveThreshold\"->True the points picked are away from the regression functions.";
QRMonSeparate::usage = "QRMonSeparate[data_, opts___] separates the argument by the regression functions in the context. \
If no argument is given the data in the monad object is separated.";
QRMonSeparateToFractions::usage = "QRMonSeparateToFractions[data_, opts___] separates the argument by the regression functions \
in the context and find the corresponding fractions. \
If no argument is given the data in the monad object is separated.";
QRMonBandsSequence::usage = "Maps the time series values into a sequence of band indices derived from the regression quantiles.";
QRMonGridSequence::usage = "Maps the time series values into a sequence of indices derived from a values grid.";
QRMonMovingAverage::usage = "Moving average over a specified number of elements or a list of weights.";
QRMonMovingMedian::usage = "Moving median over a specified number of elements.";
QRMonMovingMap::usage = "Moving map with a specified function using a given window specification.";
QRMonSimulate::usage = "Simulates a time series using computed regression quantiles.";
QRMonLocalExtrema::usage = "Finds local extrema.";
QRMonFindLocalExtrema::usage = "Finds local extrema. (Same as QRMonLocalExtrema.)";
QRMonChowTestStatistic::usage = "Computes the Chow test statistic for identifying structural breaks in time series.";
Begin["`Private`"];
Needs["MathematicaForPredictionUtilities`"];
Needs["StateMonadCodeGenerator`"];
Needs["QuantileRegression`"];
Needs["OutlierIdentifiers`"];
(**************************************************************)
(* Generation *)
(**************************************************************)
(* Generate base functions of QRMon monad (through StMon.) *)
GenerateStateMonadCode[ "MonadicQuantileRegression`QRMon", "FailureSymbol" -> $QRMonFailure, "StringContextNames" -> False ]
GenerateMonadAccessors[
"MonadicQuantileRegression`QRMon",
{"data", "regressionFunctions", "outliers", "outlierRegressionFunctions", "net",
"dataPlotOptions", "regressionFunctionsPlotOptions"},
"FailureSymbol" -> $QRMonFailure ];
(**************************************************************)
(* Setters / getters *)
(**************************************************************)
(* This is has to be re-implemented because of the use of QRMonGetData. *)
ClearAll[QRMonTakeData];
SyntaxInformation[QRMonGetData] = { "ArgumentsPattern" -> { } };
QRMonTakeData[$QRMonFailure] := $QRMonFailure;
QRMonTakeData[][$QRMonFailure] := $QRMonFailure;
QRMonTakeData[xs_, context_] := QRMonTakeData[][xs, context];
QRMonTakeData[][xs_, context_] := QRMonBind[ QRMonGetData[xs, context], QRMonTakeValue ];
QRMonTakeData[__][___] := $QRMonFailure;
Clear[QRMonSetNet];
QRMonSetNet[$QRMonFailure] := $QRMonFailure;
QRMonSetNet[xs_, context_] := QRMonSetNet[][xs, context];
QRMonSetNet[][xs_, context_] :=
Block[{net},
net =
NetChain[{
LinearLayer[15], BatchNormalizationLayer[],
ElementwiseLayer[Tanh], LinearLayer[10], BatchNormalizationLayer[],
ElementwiseLayer[Tanh], LinearLayer[1]},
"Input" -> 1, "Output" -> "Scalar" ];
QRMonUnit[ xs, Join[ context, <|"net" -> net|> ] ]
];
QRMonSetNet[net_NetChain][xs_, context_] := QRMonUnit[ xs, Join[ context, <|"net" -> net|> ] ];
QRMonSetNet[__][___] := $QRMonFailure;
(**************************************************************)
(* DataToNormalForm *)
(**************************************************************)
Clear[DataToNormalForm];
DataToNormalForm[data_, functionName_String] :=
Which[
MatrixQ[data, NumericQ] && Dimensions[data][[2]] == 2,
data,
VectorQ[data, NumericQ],
Transpose[{ Range[Length[data]], data }],
TrueQ[ Head[data] === Dataset ],
(* DatasetToMatrix is implemented in MathematicaForPredictionUtilities.m *)
DatasetToMatrix[
data,
"ExpectedColumnNames" -> {"Regressor", "Value"},
"FunctionName" -> functionName,
"FailureSymbol" -> $QRMonFailure
]
];
(**************************************************************)
(* GetData *)
(**************************************************************)
Clear[QRMonGetData];
SyntaxInformation[QRMonGetData] = { "ArgumentsPattern" -> { } };
QRMonGetData[$QRMonFailure] := $QRMonFailure;
QRMonGetData[][xs_, context_] := QRMonGetData[xs, context];
QRMonGetData[xs_, context_] :=
Block[{data},
Which[
KeyExistsQ[context, "data"] && MatrixQ[context["data"], NumericQ] && Dimensions[context["data"]][[2]] == 2,
QRMonUnit[ context["data"], context],
KeyExistsQ[context, "data"] && VectorQ[context["data"], NumericQ],
data = DataToNormalForm[context["data"], "QRMonGetData"];
QRMonUnit[ data, Join[context, <| "data" -> data |>] ],
KeyExistsQ[context, "data"] && TrueQ[ Head[context["data"]] === Dataset ],
data = DataToNormalForm[context["data"], "QRMonGetData"];
If[ TrueQ[data === $QRMonFailure],
$QRMonFailure,
QRMonUnit[ SetPrecision[data, Precision[data]], context]
],
KeyExistsQ[context, "data"] && MatchQ[context["data"], (_TimeSeries | _TemporalData)],
data = context["data"]["Path"] /. Quantity[x_, u_] :> x;
QRMonUnit[ SetPrecision[data, Precision[data]], context],
MatrixQ[xs, NumericQ] && Dimensions[xs][[2]] == 2,
QRMonUnit[xs, context],
VectorQ[xs, NumericQ],
QRMonUnit[ Transpose[{ Range[Length[xs]], xs }], context],
TrueQ[ Head[xs] === Dataset ],
data = DataToNormalForm[xs, "QRMonGetData"];
If[ TrueQ[data === $QRMonFailure],
$QRMonFailure,
QRMonUnit[ SetPrecision[data, Precision[data]], context]
],
MatchQ[xs, (_TimeSeries | _TemporalData)],
data = xs["Path"] /. Quantity[x_, u_] :> x;
QRMonUnit[ SetPrecision[data, Precision[data]], context],
True,
Echo["Cannot find data.", "GetData:"];
$QRMonFailure
]
];
QRMonGetData[___][xs_, context_Association] := $QRMonFailure;
(**************************************************************)
(* Echo data summary *)
(**************************************************************)
Clear[QRMonEchoDataSummary];
SyntaxInformation[QRMonEchoDataSummary] = { "ArgumentsPattern" -> { } };
QRMonEchoDataSummary[$QRMonFailure] := $QRMonFailure;
QRMonEchoDataSummary[xs_, context_] := QRMonEchoDataSummary[][xs, context];
QRMonEchoDataSummary[][xs_, context_] :=
Fold[ QRMonBind, QRMonUnit[xs, context], { QRMonGetData, QRMonEchoFunctionValue["Data summary:", RecordsSummary[#, {"Regressor", "Value"}]& ] } ]
QRMonEchoDataSummary[___][__] := $QRMonFailure;
(**************************************************************)
(* DeleteMissing *)
(**************************************************************)
Clear[QRMonDeleteMissing];
SyntaxInformation[QRMonDeleteMissing] = { "ArgumentsPattern" -> { } };
QRMonDeleteMissing[$QRMonFailure] := $QRMonFailure;
QRMonDeleteMissing[xs_, context_] := QRMonDeleteMissing[][xs, context];
QRMonDeleteMissing[][xs_, context_] :=
Block[{data},
data = QRMonTakeData[xs, context];
If[ data === $QRMonFailure,
$QRMonFailure,
(*ELSE*)
data = DeleteMissing[data, 1, 2];
QRMonUnit[ data, Join[ context, <|"data" -> data|>] ]
]
];
QRMonDeleteMissing[___][__] := $QRMonFailure;
(**************************************************************)
(* Rescale *)
(**************************************************************)
Clear[QRMonRescale];
SyntaxInformation[QRMonRescale] = { "ArgumentsPattern" -> { OptionsPattern[] } };
Options[QRMonRescale] = {Axes -> {True, False}};
QRMonRescale[$QRMonFailure] := $QRMonFailure;
QRMonRescale[xs_, context_] := QRMonRescale[][xs, context];
QRMonRescale[opts : OptionsPattern[]][xs_, context_] :=
Block[{data, axesOpt},
axesOpt = OptionValue[QRMonRescale, Axes];
data = QRMonTakeData[ xs, context ];
If[data === $QRMonFailure, Return[$QRMonFailure]];
Which[
TrueQ[ axesOpt == {False, False}] || TrueQ[ !axesOpt ] || TrueQ[ axesOpt === None ],
QRMonUnit[xs, context],
TrueQ[axesOpt] || TrueQ[axesOpt == {True, True}] ||
TrueQ[ ToLowerCase[axesOpt] == "both" || ToLowerCase[axesOpt] == "path" || axesOpt === All ] ||
TrueQ[ ListQ[axesOpt] && Length[Intersection[axesOpt, {"x", "y", "time"}]] == 2 ] ||
TrueQ[ ListQ[axesOpt] && Length[Intersection[axesOpt, {"x", "value", "time"}]] == 2 ],
data = Transpose[Rescale /@ Transpose[data]];
QRMonUnit[ data, Join[ context, <|"data" -> data|>] ],
TrueQ[ axesOpt == {True, False}] ||
TrueQ[ axesOpt == "x" || axesOpt == "t"],
data = Transpose[{Rescale[data[[All, 1]]], data[[All, 2]]}];
QRMonUnit[ data, Join[ context, <|"data" -> data|>] ],
TrueQ[ axesOpt == {False, True}] ||
TrueQ[ axesOpt == "y" || axesOpt == "value"],
data = Transpose[{data[[All, 1]], Rescale[data[[All, 2]]]}];
QRMonUnit[ data, Join[ context, <|"data" -> data|>] ],
True,
$QRMonFailure
]
];
QRMonRescale[___][__] := $QRMonFailure;
(**************************************************************)
(* LeastSquaresFit *)
(**************************************************************)
Clear[QRMonLeastSquaresFit];
SyntaxInformation[QRMonLeastSquaresFit] = { "ArgumentsPattern" -> { _, _. } };
QRMonLeastSquaresFit[$QRMonFailure] := $QRMonFailure;
QRMonLeastSquaresFit[xs_, context_Association] := $QRMonFailure;
QRMonLeastSquaresFit[n_Integer][xs_, context_] :=
QRMonLeastSquaresFit[{ n, {-0.95, 0.95} }][xs, context];
(* This signature is not that needed for LeastSquaresFit, it is implemented for symmetry with QuantileRegressionFit . *)
QRMonLeastSquaresFit[{ n_Integer, r : {_?NumericQ, _?NumericQ} }][xs_, context_] :=
Fold[
QRMonBind,
QRMonUnit[xs, context],
{QRMonGetData,
QRMonLeastSquaresFit[Table[ChebyshevT[i, Rescale[x, MinMax[#[[All, 1]]], r]], {i, 0, n}], x][##]&}
];
QRMonLeastSquaresFit[funcs_List][xs_, context_] :=
Block[{var},
var =
With[{globalQ = Context@# === "Global`" &},
DeleteDuplicates@Cases[funcs, _Symbol?globalQ, Infinity]
];
If[ Length[var] == 0,
$QRMonFailure,
(*ELSE*)
QRMonLeastSquaresFit[funcs, First[var]][xs, context]
]
];
QRMonLeastSquaresFit[funcs_List, var_Symbol][xs_, context_] :=
Block[{data, qFunc},
data = QRMonBind[ QRMonGetData[xs, context], QRMonTakeValue ];
qFunc = Fit[data, funcs, var];
qFunc = Function[ Evaluate[ qFunc /. var -> Slot[1] ] ];
QRMonUnit[qFunc,
Join[context,
<|"data" -> data,
"regressionFunctions" -> Join[ Lookup[context, "regressionFunctions", <||>], <| "mean" -> qFunc |> ] |>
]
]
];
QRMonLeastSquaresFit[___][__] := $QRMonFailure;
Clear[QRMonFit];
QRMonFit = QRMonLeastSquaresFit;
(**************************************************************)
(* Quantile regression *)
(**************************************************************)
Clear[QRMonQuantileRegression];
SyntaxInformation[QRMonQuantileRegression] = { "ArgumentsPattern" -> { _., _., OptionsPattern[] } };
Options[QRMonQuantileRegression] =
Join[
{ "Knots" -> 12, "Probabilities" -> {0.25, 0.5, 0.75} },
Options[QuantileRegression]
];
Options[QRMonQuantileRegression] =
ReplaceAll[
Options[QRMonQuantileRegression],
HoldPattern[Method -> _] -> ( Method -> {LinearProgramming, Method -> "CLP", Tolerance -> 10^(-3)} ) ];
QRMonQuantileRegression[$QRMonFailure] := $QRMonFailure;
QRMonQuantileRegression[xs_, context_Association] := QRMonQuantileRegression[ Options[QRMonQuantileRegression] ][xs, context];
QRMonQuantileRegression[][xs_, context_Association] := QRMonQuantileRegression[ Options[QRMonQuantileRegression] ][xs, context];
QRMonQuantileRegression[opts : OptionsPattern[]][xs_, context_Association] :=
Block[{knots, probabilities},
knots = OptionValue[QRMonQuantileRegression, "Knots"];
If[ ! MatchQ[ knots, ( _Integer | { _?NumberQ..} ) ],
Echo[
"The value of the option \"Knots\" is expected to be a knots specification, (_Integer | {_?NumberQ..}). ",
"QRMonQuantileRegression:"];
Return[$QRMonFailure];
];
probabilities = OptionValue[QRMonQuantileRegression, "Probabilities"];
If[ ! MatchQ[ probabilities, ( _?NumberQ | { _?NumberQ..} ) ],
Echo[
"The value of the option \"Probabilities\" is expected to be a probabilities specification, (_?NumberQ | {_?NumberQ..}). ",
"QRMonQuantileRegression:"];
Return[$QRMonFailure];
];
probabilities = If[ NumberQ[probabilities], {probabilities}, probabilities ];
QRMonQuantileRegression[knots, probabilities, opts][xs, context]
];
QRMonQuantileRegression[knots : (_Integer | {_?NumberQ ..}), opts : OptionsPattern[]][xs_, context_] :=
QRMonQuantileRegression[knots, {0.25, 0.5, 0.75}, opts][xs, context];
QRMonQuantileRegression[knots : (_Integer | {_?NumberQ ..}), p_?NumberQ, opts : OptionsPattern[]][xs_, context_] :=
QRMonQuantileRegression[knots, {p}, opts][xs, context];
QRMonQuantileRegression[knots : (_Integer | {_?NumberQ ..}), ps : {_?NumberQ..}, opts : OptionsPattern[]][xs_, context_] :=
Block[{data, qFuncs},
data = QRMonBind[ QRMonGetData[xs, context], QRMonTakeValue ];
qFuncs = QuantileRegression[data, knots, ps, FilterRules[ {opts}, Options[QuantileRegression] ] ];
If[ ListQ[qFuncs] && Length[qFuncs] == Length[ps],
qFuncs = AssociationThread[ps, qFuncs];
QRMonUnit[qFuncs, Join[context, <|"data" -> data, "regressionFunctions" -> Join[ Lookup[context, "regressionFunctions", <||>], qFuncs] |> ] ],
(* ELSE *)
$QRMonFailure
]
];
QRMonQuantileRegression[___][__] :=
Block[{},
Echo[
StringJoin[
"The first argument is expected to be a knots specification, ( _Integer | {_?NumberQ..} ). ",
"The second optional argument is expected to be a probabilities specification, ( _?NumberQ | {_?NumberQ..} )."
],
"QRMonQuantileRegression:"
];
$QRMonFailure
];
Clear[QRMonRegression];
QRMonRegression = QRMonQuantileRegression;
(**************************************************************)
(* Quantile regression fit *)
(**************************************************************)
Clear[QRMonQuantileRegressionFit];
SyntaxInformation[QRMonQuantileRegressionFit] = { "ArgumentsPattern" -> { _., _., _., OptionsPattern[] } };
Options[QRMonQuantileRegressionFit] =
Join[
{ "Functions" -> 12, "Variable" -> Automatic, "Probabilities" -> {0.25, 0.5, 0.75} },
Options[QuantileRegressionFit]
];
Options[QRMonQuantileRegressionFit] =
ReplaceAll[
Options[QRMonQuantileRegressionFit],
HoldPattern[Method -> _] -> ( Method -> {LinearProgramming, Method -> "CLP"} ) ];
QRMonQuantileRegressionFit[$QRMonFailure] := $QRMonFailure;
QRMonQuantileRegressionFit[xs_, context_Association] := QRMonQuantileRegressionFit[ Options[QRMonQuantileRegressionFit] ][xs, context];
QRMonQuantileRegressionFit[][xs_, context_Association] := QRMonQuantileRegressionFit[ Options[QRMonQuantileRegressionFit] ][xs, context];
QRMonQuantileRegressionFit[opts : OptionsPattern[]][xs_, context_Association] :=
Block[{funcs, var, probabilities},
funcs = OptionValue[QRMonQuantileRegressionFit, "Functions"];
If[ ! ( IntegerQ[funcs] || ListQ[ funcs ] ),
Echo[
"The value of the option \"Functions\" is expected to be a list of functions or an integer. ",
"QRMonQuantileRegressionFit:"];
Return[$QRMonFailure];
];
var = OptionValue[QRMonQuantileRegressionFit, "Variable"];
If[ ! ( TrueQ[var === Automatic] || TrueQ[ Head[var] === Symbol ] ) ,
Echo[
"The value of the option \"Variabls\" is expected to be a symbol or Automatic. ",
"QRMonQuantileRegressionFit:"];
Return[$QRMonFailure];
];
probabilities = OptionValue[QRMonQuantileRegressionFit, "Probabilities"];
If[ ! MatchQ[ probabilities, ( _?NumberQ | { _?NumberQ..} ) ],
Echo[
"The value of the option \"Probabilities\" is expected to be a probabilities specification, (_?NumberQ | {_?NumberQ..}). ",
"QRMonQuantileRegressionFit:"];
Return[$QRMonFailure];
];
probabilities = If[ NumberQ[probabilities], {probabilities}, probabilities ];
If[ IntegerQ[funcs],
QRMonQuantileRegressionFit[funcs, probabilities, opts][xs, context],
(* ELSE *)
QRMonQuantileRegressionFit[funcs, var, probabilities, opts][xs, context]
]
];
QRMonQuantileRegressionFit[funcs : (_List | _Integer), opts : OptionsPattern[]][xs_, context_] :=
QRMonQuantileRegressionFit[funcs, {0.25, 0.5, 0.75}, opts][xs, context];
QRMonQuantileRegressionFit[funcs_List, p_?NumberQ, opts : OptionsPattern[]][xs_, context_] :=
QRMonQuantileRegressionFit[funcs, {p}, opts][xs, context];
QRMonQuantileRegressionFit[n_Integer, args___][xs_, context_] :=
QRMonQuantileRegressionFit[{ n, {-0.95, 0.95} }, args][xs, context];
QRMonQuantileRegressionFit[{ n_Integer, r : {_?NumericQ, _?NumericQ} }, args___][xs_, context_] :=
Fold[
QRMonBind,
QRMonUnit[xs, context],
{QRMonGetData,
QRMonQuantileRegressionFit[Table[ChebyshevT[i, Rescale[x, MinMax[#[[All, 1]]], r]], {i, 0, n}], x, args][##]&}
];
QRMonQuantileRegressionFit[funcs_List, ps : {_?NumberQ..}, opts : OptionsPattern[]][xs_, context_] :=
QRMonQuantileRegressionFit[funcs, Automatic, ps, opts][xs, context];
QRMonQuantileRegressionFit[funcs_List, Automatic, ps : {_?NumberQ..}, opts : OptionsPattern[]][xs_, context_] :=
Block[{var},
var =
With[{globalQ = Context@# === "Global`" &},
DeleteDuplicates@Cases[funcs, _Symbol?globalQ, Infinity]
];
If[ Length[var] == 0,
$QRMonFailure,
(*ELSE*)
QRMonQuantileRegressionFit[funcs, First[var], ps, opts][xs, context]
]
];
QRMonQuantileRegressionFit[funcs_List, var_Symbol, opts : OptionsPattern[]][xs_, context_] :=
QRMonQuantileRegressionFit[funcs, var, {0.25, 0.5, 0.75}, opts][xs, context];
QRMonQuantileRegressionFit[funcs_List, var_Symbol, ps : {_?NumberQ..}, opts : OptionsPattern[]][xs_, context_] :=
Block[{data, qFuncs},
data = QRMonBind[ QRMonGetData[xs, context], QRMonTakeValue ];
qFuncs = QuantileRegressionFit[data, funcs, var, ps, FilterRules[ {opts}, Options[QuantileRegressionFit] ] ];
If[ ListQ[qFuncs] && Length[qFuncs] == Length[ps],
qFuncs = Map[Function[{expr}, Function[Evaluate[expr /. var -> Slot[1]]]], qFuncs];
qFuncs = AssociationThread[ps, qFuncs];
QRMonUnit[qFuncs, Join[context, <|"data" -> data, "regressionFunctions" -> Join[ Lookup[context, "regressionFunctions", <||>], qFuncs] |> ] ],
(* ELSE *)
$QRMonFailure
]
];
QRMonQuantileRegressionFit[___][__] := $QRMonFailure;
Clear[QRMonRegressionFit];
QRMonRegressionFit = QRMonQuantileRegressionFit;
(**************************************************************)
(* Net regression *)
(**************************************************************)
Clear[QRMonNetRegression];
Options[QRMonNetRegression] = Prepend[Options[NetTrain], InterpolationOrder -> 3];
QRMonNetRegression[$QRMonFailure] := $QRMonFailure;
QRMonNetRegression[xs_, context_Association] := QRMonNetRegression[][xs, context];
QRMonNetRegression[][xs_, context_Association] := QRMonNetRegression[0.75][xs, context];
QRMonNetRegression[opts : OptionsPattern[]][xs_, context_] :=
QRMonNetRegression[0.75, opts][xs, context];
QRMonNetRegression[splitRatio_?NumberQ, opts : OptionsPattern[]][xs_, context_] :=
Block[{interpolationOrder, data, qFunc, netRegressionPoints, trainingData, testData, trainedNet, lowestVal},
If[ ! KeyExistsQ[context, "net"],
Echo["Cannot find a neural net. (Context key \"net\".).", "QRMonNetRegression:"];
Return[$QRMonFailure]
];
interpolationOrder = OptionValue[QRMonNetRegression, InterpolationOrder];
data = QRMonBind[ QRMonGetData[xs, context], QRMonTakeValue ];
{trainingData, testData} = TakeDrop[RandomSample[data], Floor[splitRatio * Length[data]]];
trainingData = Rule @@@ trainingData;
trainingData[[All, 1]] = List /@ trainingData[[All, 1]];
testData = Rule @@@ testData;
testData[[All, 1]] = List /@ testData[[All, 1]];
{trainedNet, lowestVal} =
NetTrain[
context["net"], trainingData, {"TrainedNet", "ValidationLoss"},
ValidationSet -> testData,
DeleteCases[ {opts}, HoldPattern[InterpolationOrder -> _] ]
];
netRegressionPoints = Transpose[{data[[All, 1]], trainedNet /@ data[[All, 1]]}];
qFunc = Interpolation[ Union[netRegressionPoints], InterpolationOrder -> Round[interpolationOrder] ];
QRMonUnit[qFunc,
Join[context,
<|"data" -> data,
"net" -> trainedNet,
"netRegressionPoints" -> netRegressionPoints,
"regressionFunctions" -> Join[ Lookup[context, "regressionFunctions", <||>], <| "net" -> qFunc |> ] |>
]
]
] /; 0 < splitRatio < 1;
QRMonNetRegression[___][__] :=
Block[{},
Echo["The first argument is expected to be a split ratio specification: a number between 0 and 1.", "QRMonNetRegression:"];
$QRMonFailure
];
(**************************************************************)
(* Evaluate *)
(**************************************************************)
(* See InterpolationFunction[___]["Evaluate"[{0.2, 0.3, 1}]] *)
(* Probably can be optimized. *)
Clear[QRMonEvaluate];
SyntaxInformation[QRMonEvaluate] = { "ArgumentsPattern" -> {_} };
QRMonEvaluate[$QRMonFailure] := $QRMonFailure;
QRMonEvaluate[xs_, context_Association] := $QRMonFailure;
QRMonEvaluate[___][$QRMonFailure] := $QRMonFailure;
QRMonEvaluate[n_?AtomQ][x_, context_] :=
If[KeyExistsQ[context, "regressionFunctions"],
QRMonUnit[ Map[#[n]&, context["regressionFunctions"] ], context ],
(*ELSE*)
$QRMonFailure
];
QRMonEvaluate[arr_List][x_, context_] :=
If[KeyExistsQ[context, "regressionFunctions"],
QRMonUnit[ Map[Function[{qf}, Map[qf, arr, {-1}]], context["regressionFunctions"] ], context ],
(*ELSE*)
$QRMonFailure
];
QRMonEvaluate[___][__] := $QRMonFailure;
(**************************************************************)
(* Plot *)
(**************************************************************)
Clear[QRMonPlot];
SyntaxInformation[QRMonPlot] = { "ArgumentsPattern" -> {OptionsPattern[]} };
Options[QRMonPlot] = Join[ {"Echo" -> True, "DateListPlot" -> False}, Options[ListPlot] ];
QRMonPlot[QRMonPlot] := $QRMonFailure;
QRMonPlot[xs_, context_Association] := QRMonPlot[][xs, context];
QRMonPlot[opts : OptionsPattern[]][xs_, context_] :=
Block[{data, res, listPlotFunc = ListPlot, listPlotOpts, plotOpts},
data = QRMonTakeData[xs, context];
If[data === $QRMonFailure, Return[$QRMonFailure]];
If[ TrueQ[OptionValue[QRMonPlot, "DateListPlot"]], listPlotFunc = DateListPlot ];
listPlotOpts = Normal @ KeyTake[ {opts}, First /@ Options[listPlotFunc]];
plotOpts = Normal @ KeyTake[ {opts}, First /@ Options[Plot]];
plotOpts = DeleteCases[plotOpts, HoldPattern[PlotStyle -> _] ];
If[ KeyExistsQ[context, "dataPlotOptions"],
listPlotOpts = Join[ context["dataPlotOptions"], listPlotOpts];
];
If[ KeyExistsQ[context, "regressionFunctionsPlotOptions"],
plotOpts = Join[ context["regressionFunctionsPlotOptions"], plotOpts];
];
res =
Which[
KeyExistsQ[context, "regressionFunctions"],
Show[{
listPlotFunc[data, listPlotOpts, Joined -> False, PlotRange -> All, ImageSize -> Medium, PlotTheme -> {"Default", "Frame"}],
Plot[Evaluate[Through[Values[context["regressionFunctions"]][x]]], {x, Min[data[[All, 1]]], Max[data[[All, 1]]]},
Evaluate[plotOpts],
PerformanceGoal -> "Speed",
PlotLegends -> Keys[context["regressionFunctions"]]
]
}],
True,
listPlotFunc[data, listPlotOpts, Joined -> False, PlotRange -> All, ImageSize -> Medium, PlotTheme -> {"Default", "Frame"}]
];
If[ TrueQ[OptionValue[QRMonPlot, "Echo"]],
Echo[res, "Plot:"];
];
QRMonUnit[res, Join[ context, <|"data" -> data|>] ]
];
QRMonPlot[__][__] := $QRMonFailure;
(**************************************************************)
(* DateListPlot *)
(**************************************************************)
Clear[QRMonDateListPlot];
SyntaxInformation[QRMonDateListPlot] = { "ArgumentsPattern" -> {OptionsPattern[]} };
Options[QRMonDateListPlot] = Options[QRMonPlot];
QRMonDateListPlot[$QRMonFailure] := $QRMonFailure;
QRMonDateListPlot[xs_, context_Association] := QRMonPlot["DateListPlot" -> True][xs, context];
QRMonDateListPlot[opts : OptionsPattern[]][xs_, context_] := QRMonPlot["DateListPlot" -> True, opts][xs, context];
QRMonDateListPlot[__][__] := $QRMonFailure;
(**************************************************************)
(* Errors *)
(**************************************************************)
Clear[QRMonErrors];
SyntaxInformation[QRMonErrors] = { "ArgumentsPattern" -> {OptionsPattern[]} };
Options[QRMonErrors] = { "RelativeErrors" -> True };
QRMonErrors[$QRMonFailure] := $QRMonFailure;
QRMonErrors[xs_, context_Association] := QRMonErrors[][xs, context];
QRMonErrors[][xs_, context_] := QRMonErrors["RelativeErrors" -> True][xs, context];
QRMonErrors[opts : OptionsPattern[]][xs_, context_] :=
Block[{res, relativeErrorsQ},
relativeErrorsQ = TrueQ[OptionValue[QRMonErrors, "RelativeErrors"]];
res =
Association @
KeyValueMap[
Function[{k, f},
k -> Map[ Function[{p}, {p[[1]], (p[[2]] - f[p[[1]]]) / If[ !relativeErrorsQ || p[[2]] == 0, 1, p[[2]] ]}], context["data"] ]
],
context["regressionFunctions"]
];
QRMonUnit[res, context]
];
QRMonErrors[__][__] := $QRMonFailure;
(**************************************************************)
(* Error plots *)
(**************************************************************)
Clear[QRMonErrorPlots];
SyntaxInformation[QRMonErrorPlots] = { "ArgumentsPattern" -> {OptionsPattern[]} };
Options[QRMonErrorPlots] = Join[ {"Echo" -> True, "DateListPlot" -> False, "RelativeErrors" -> True}, Options[ListPlot] ];
QRMonErrorPlots[$QRMonFailure] := $QRMonFailure;
QRMonErrorPlots[xs_, context_Association] := QRMonErrorPlots[][xs, context];
QRMonErrorPlots[opts : OptionsPattern[]][xs_, context_] :=
Block[{res, listPlotFunc = ListPlot, listPlotOpts, relativeErrorsQ},
listPlotFunc = If[ TrueQ[OptionValue[QRMonErrorPlots, "DateListPlot"]], DateListPlot, ListPlot ];
listPlotOpts = Normal @ KeyTake[ {opts}, First /@ Options[listPlotFunc]];
relativeErrorsQ = TrueQ[OptionValue[QRMonErrorPlots, "RelativeErrors"]];
(* The error values can be reused from QRMonErrors, but it seems easier to just computed them here. *)
res =
KeyValueMap[
Function[{k, f},
k ->
listPlotFunc[
Map[Function[{p}, {p[[1]], (p[[2]] - f[p[[1]]]) / If[ !relativeErrorsQ || p[[2]] == 0, 1, p[[2]] ] }], context["data"] ],
listPlotOpts,
Joined -> False, PlotRange -> All, Filling -> Axis, Frame -> True, ImageSize -> Medium, PlotTheme -> {"Default", "Frame"}]
],
context["regressionFunctions"]
];
If[ TrueQ[OptionValue[QRMonErrorPlots, "Echo"]],
Echo[res, If[relativeErrorsQ, "Relative error plots:", "Error plots:"]];
];
QRMonUnit[res, context]
];
QRMonErrorPlots[__][__] := $QRMonFailure;
(**************************************************************)
(* Conditional distribution *)
(**************************************************************)
Clear[CDFEstimate];
CDFEstimate[qFuncs_Association, t0_, intOrder : _Integer : 1] :=
Interpolation[Transpose[{Through[Values[qFuncs][t0]], Keys[qFuncs]}], InterpolationOrder -> intOrder];
Clear[CDFPDFPlot];
CDFPDFPlot[t0_?NumberQ, qCDFInt_InterpolatingFunction, qs : {_?NumericQ..}, opts : OptionsPattern[]] :=
Block[{},
Plot[
{qCDFInt[x], qCDFInt'[x]},
{x, qCDFInt["Domain"][[1, 1]], qCDFInt["Domain"][[1, 2]]},
opts, GridLines -> {None, qs}, PlotRange -> {0, 1}, Axes -> False, Frame -> True]
];
Clear[QRMonConditionalCDF];
SyntaxInformation[QRMonConditionalCDF] = { "ArgumentsPattern" -> {_} };