-
Notifications
You must be signed in to change notification settings - Fork 97
/
Copy pathMonadicLatentSemanticAnalysis.m
2064 lines (1476 loc) · 78.4 KB
/
MonadicLatentSemanticAnalysis.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Monadic Latent Semantic Analysis Mathematica package
Copyright (C) 2017 Anton Antonov
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
Written by Anton Antonov,
antononcube @ gmail . com,
Windermere, Florida, USA.
*)
(*
Mathematica is (C) Copyright 1988-2017 Wolfram Research, Inc.
Protected by copyright law and international treaties.
Unauthorized reproduction or distribution subject to severe civil
and criminal penalties.
Mathematica is a registered trademark of Wolfram Research, Inc.
*)
(* :Title: MonadicLatentSemanticAnalysis *)
(* :Context: MonadicLatentSemanticAnalysis` *)
(* :Author: Anton Antonov *)
(* :Date: 2017-10-06 *)
(* Created with the Wolfram Language Plugin for IntelliJ, see http://wlplugin.halirutan.de/ . *)
(* :Package Version: 1.0 *)
(* :Mathematica Version: *)
(* :Copyright: (c) 2017 Anton Antonov *)
(* :Keywords: *)
(* :Discussion:
# Introduction
This file (package) provides a software monad implementation for the following Latent Semantic Analysis (LSA)
main sequence of steps :
1. ingesting a collection of documents;
2. creating a document-term matrix (linear vector space representation);
3. facilitating term-paragraph matrix creation or other breakdowns;
4. apply different type of term-weighting functions;
5. extract topics using NNMF (or SVD) with required parameters;
6. provide topic interpretation;
7. produce corresponding statistical thesauri;
8. provide different statistics over the document collection.
We can see this monadic implementation as a wrapper interface to the functions provided by the packages [1,2,3];
those functions are described in [4].
# Usage example
(* Get text data. *)
speeches = ResourceData[ResourceObject["Presidential Nomination Acceptance Speeches"]];
texts = Normal[speeches[[All, "Text"]]];
(* Run the main processing pipeline. *)
res =
LSAMonUnit[texts]⟹
LSAMonMakeDocumentTermMatrix[{}, Automatic]⟹
LSAMonApplyTermWeightFunctions[]⟹
LSAMonExtractTopics["MinNumberOfDocumentsPerTerm" -> 5, "NumberOfTopics" -> 20, Method -> "NNMF", "MaxSteps" -> 6, "PrintProfilingInfo" -> True];
(* Show statistical thesaurus in two different ways. *)
res⟹
LSAMonExtractStatisticalThesaurus[{"arms", "banking", "economy", "education", "freedom", "tariff", "welfare"}, 6]⟹
LSAMonRetrieveFromContext["statisticalThesaurus"]⟹
LSAMonEchoValue⟹
LSAMonEchoStatisticalThesaurusTable[];
# References
[1] Anton Antonov, Implementation of document-term matrix construction and re-weighting functions in Mathematica, (2013),
MathematicaForPrediction at GitHub.
https://github.com/antononcube/MathematicaForPrediction/blob/master/DocumentTermMatrixConstruction.m
[2] Anton Antonov, Implementation of the Non-Negative Matrix Factorization algorithm in Mathematica, (2013),
https://github.com/antononcube/MathematicaForPrediction/blob/master/NonNegativeMatrixFactorization.m
[3] Anton Antonov, Independent Component Analysis Mathematica package, (2016),
https://github.com/antononcube/MathematicaForPrediction/blob/master/IndependentComponentAnalysis.m
[4] Anton Antonov, "Topic and thesaurus extraction from a document collection", (2013),
MathematicaForPrediction at GitHub.
https://github.com/antononcube/MathematicaForPrediction/blob/master/Documentation/Topic%20and%20thesaurus%20extraction%20from%20a%20document%20collection.pdf
Anton Antonov
2017-10-06
*)
(**************************************************************)
(* Importing packages (if needed) *)
(**************************************************************)
If[Length[DownValues[StateMonadCodeGenerator`GenerateStateMonadCode]] == 0,
Echo["StateMonadCodeGenerator.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MonadicProgramming/StateMonadCodeGenerator.m"]
];
If[Length[DownValues[SSparseMatrix`ToSSparseMatrix]] == 0,
Echo["SSparseMatrix.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/SSparseMatrix.m"]
];
If[Length[DownValues[DocumentTermMatrixConstruction`DocumentTermMatrix]] == 0,
Echo["DocumentTermMatrixConstruction.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/DocumentTermMatrixConstruction.m"]
];
If[Length[DownValues[NonNegativeMatrixFactorization`NonNegativeMatrixFactorization]] == 0,
Echo["NonNegativeMatrixFactorization.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/NonNegativeMatrixFactorization.m"]
];
If[Length[DownValues[IndependentComponentAnalysis`IndependentComponentAnalysis]] == 0,
Echo["IndependentComponentAnalysis.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/IndependentComponentAnalysis.m"]
];
If[Length[DownValues[CrossTabulate`CrossTabulate]] == 0,
Echo["CrossTabulate.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/CrossTabulate.m"]
];
If[Length[DownValues[OutlierIdentifiers`OutlierPosition]] == 0,
Echo["OutlierIdentifiers.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/OutlierIdentifiers.m"]
];
If[Length[DownValues[MathematicaForPredictionUtilities`RecordsSummary]] == 0,
Echo["MathematicaForPredictionUtilities.m", "Importing from GitHub:"];
Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MathematicaForPredictionUtilities.m"]
];
(**************************************************************)
(* Package definition *)
(**************************************************************)
BeginPackage["MonadicLatentSemanticAnalysis`"];
$LSAMonFailure::usage = "Failure symbol for the monad LSAMon.";
LSAMonApplyTermWeightFunctions::usage = "Apply term weight functions to entries of the document-term matrix.";
LSAMonInterpretBasisVector::usage = "Interpret the a specified basis vector.";
LSAMonEchoStatisticalThesaurusTable::usage = "Echo the statistical thesaurus entries for a specified list of words.";
LSAMonEchoStatisticalThesaurus::usage = "Echo the statistical thesaurus entries for a specified list of words. \
Synonym of LSAMonEchoStatisticalThesaurusTable.";
LSAMonEchoDocumentsStatistics::usage = "Echo statistics for the text collection.";
LSAMonEchoDocumentTermMatrixStatistics::usage = "Echo document-term matrix statistics.";
LSAMonEchoTopicsTable::usage = "Echo the a table with the extracted topics.";
LSAMonGetDocuments::usage = "Get monad's document collection.";
LSAMonMakeDocumentTermMatrix::usage = "Make the document-term matrix.";
LSAMonMakeGraph::usage = "Make a graph of the document-term, document-document, or term-term relationships.";
LSAMonMakeBipartiteGraphMatrix::usage = "Make a bi-partite graph matrix.";
LSAMonFindMostImportantDocuments::usage = "Find the most important texts in the text collection.";
LSAMonExtractStatisticalThesaurus::usage = "Extract the statistical thesaurus for specified list of words.";
LSAMonDocumentCollectionQ::usage = "Gives True if the argument is a text collection.";
LSAMonExtractTopics::usage = "Extract topics.";
LSAMonNormalizeMatrixProduct::usage = "LSAMonNormalizeMatrixProduct[ \"Normalized\" -> (Left|Right) ] \
normalize the matrix factors.";
LSAMonRepresentDocumentTagsByTopics::usage = "Find the topic representation corresponding to a list of tags. \
Each monad document is expected to have a tag. One tag might correspond to multiple documents.";
LSAMonRepresentByTerms::usage = "Find the terms representation of a matrix or a document.";
LSAMonRepresentByTopics::usage = "Find the topics representation of a matrix or a document.";
LSAMonMakeTopicsTable::usage = "Make a table of topics.";
LSAMonTakeTexts::usage = "Gives the value of the key \"texts\" from the monad context.";
LSAMonTakeMatrix::usage = "Gives SSparseMatrix object of the value of the key \"docTermMat\" from the monad context.";
LSAMonTakeWeightedMatrix::usage = "Gives SSparseMatrix object of the value of the key \"wDocTermMat\" from the monad context.";
FindMostImportantSentences::usage = "FindMostImportantSentences[sentences : ( _String | {_String ..} ), nTop_Integer : 5, opts : OptionsPattern[]] \
finds the most important sentences in a text or a list of sentences.";
LSAMonImportFromDirectory::usage = "LSAMonImportFromDirectory[dirName, prefix, infix] imports an LSA object from a directory";
Begin["`Private`"];
Needs["MathematicaForPredictionUtilities`"];
Needs["StateMonadCodeGenerator`"];
Needs["SSparseMatrix`"];
Needs["DocumentTermMatrixConstruction`"];
Needs["NonNegativeMatrixFactorization`"];
Needs["IndependentComponentAnalysis`"];
Needs["CrossTabulate`"];
Needs["OutlierIdentifiers`"];
Needs["ParetoPrincipleAdherence`"];
(**************************************************************)
(* Generation *)
(**************************************************************)
(* Generate base functions of LSAMon monad (through StMon.) *)
GenerateStateMonadCode[ "MonadicLatentSemanticAnalysis`LSAMon", "FailureSymbol" -> $LSAMonFailure, "StringContextNames" -> False ];
(**************************************************************)
(* Setters and takers *)
(**************************************************************)
GenerateMonadAccessors[
"MonadicLatentSemanticAnalysis`LSAMon",
{"documents", "terms", "documentTermMatrix", "weightedDocumentTermMatrix",
"stemmingRules", "stopWords",
"globalWeights", "globalWeightFunction", "localWeightFunction", "normalizerFunction",
"topicColumnPositions", "automaticTopicNames", "statisticalThesaurus", "topicsTable", "method" },
"FailureSymbol" -> $LSAMonFailure ];
GenerateMonadAccessors[
"MonadicLatentSemanticAnalysis`LSAMon",
{"W", "H" },
"FailureSymbol" -> $LSAMonFailure, "DecapitalizeElementName" -> False ];
Clear[LSAMonTakeMatrix, LSAMonTakeWeightedMatrix];
LSAMonTakeMatrix = LSAMonTakeDocumentTermMatrix;
LSAMonTakeWeightedMatrix = LSAMonTakeWeightedDocumentTermMatrix;
(**************************************************************)
(* Set document-term matrix *)
(**************************************************************)
(* Here we change the definition made with GenerateMonadAccessors. *)
Clear[LSAMonSetDocumentTermMatrix];
LSAMonSetDocumentTermMatrix[$LSAMonFailure] := $LSAMonFailure;
LSAMonSetDocumentTermMatrix[][xs_, context_] := $LSAMonFailure;
LSAMonSetDocumentTermMatrix[ smat_SSparseMatrix ][xs_, context_Association] :=
LSAMonUnit[ xs, Join[ context, <| "documentTermMatrix" -> smat |> ] ];
LSAMonSetDocumentTermMatrix[ mat_?MatrixQ ][xs_, context_] :=
Block[{smat},
smat =
ToSSparseMatrix[
SparseArray[mat],
"RowNames" -> Map[ToString, Range[Dimensions[mat][[1]]]],
"ColumnNames" -> Map[ToString, Range[Dimensions[mat][[2]]]]
];
LSAMonSetDocumentTermMatrix[smat][xs, context]
];
LSAMonSetDocumentTermMatrix[___][xs_, context_Association] :=
Block[{},
Echo[ "The argument is expected to be a matrix or a SSparseMatrix object.", "LSAMonSetDocumentTermMatrix:"];
$LSAMonFailure
];
(**************************************************************)
(* Set document-term matrix *)
(**************************************************************)
(* Here we change the definition made with GenerateMonadAccessors. *)
Clear[LSAMonSetWeightedDocumentTermMatrix];
LSAMonSetWeightedDocumentTermMatrix[$LSAMonFailure] := $LSAMonFailure;
LSAMonSetWeightedDocumentTermMatrix[][xs_, context_] := $LSAMonFailure;
LSAMonSetWeightedDocumentTermMatrix[ smat_SSparseMatrix ][xs_, context_Association] :=
LSAMonUnit[ xs, Join[ context, <| "weightedDocumentTermMatrix" -> smat |> ] ];
LSAMonSetWeightedDocumentTermMatrix[ mat_?MatrixQ ][xs_, context_] :=
Block[{smat},
smat =
ToSSparseMatrix[
SparseArray[mat],
"RowNames" -> Map[ToString, Range[Dimensions[mat][[1]]]],
"ColumnNames" -> Map[ToString, Range[Dimensions[mat][[2]]]]
];
LSAMonSetWeightedDocumentTermMatrix[smat][xs, context]
];
LSAMonSetWeightedDocumentTermMatrix[___][xs_, context_Association] :=
Block[{},
Echo[ "The argument is expected to be a matrix or a SSparseMatrix object.", "LSAMonSetWeightedDocumentTermMatrix:"];
$LSAMonFailure
];
(**************************************************************)
(* Get texts *)
(**************************************************************)
Clear[LSAMonDocumentCollectionQ];
LSAMonDocumentCollectionQ[x_] := AssociationQ[x] && ( VectorQ[ Values[x], StringQ ] || Apply[And, VectorQ[#, StringQ]& /@ Values[x] ] );
Clear[LSAMonGetDocuments];
LSAMonGetDocuments[$LSAMonFailure] := $LSAMonFailure;
LSAMonGetDocuments[][xs_, context_] := LSAMonGetDocuments[xs, context];
LSAMonGetDocuments[xs_, context_] :=
Block[{texts},
Which[
KeyExistsQ[context, "documents"] && LSAMonDocumentCollectionQ[ context["documents"] ],
LSAMonUnit[ context["documents"], context],
KeyExistsQ[context, "documents"] && VectorQ[ context["documents"], StringQ ],
texts = ToAutomaticKeysAssociation[context["documents"]];
LSAMonUnit[ texts, context],
LSAMonDocumentCollectionQ[xs],
LSAMonUnit[xs, context],
VectorQ[xs, StringQ],
texts = ToAutomaticKeysAssociation[xs];
LSAMonUnit[ texts, context],
True,
Echo["Cannot find documents.", "LSAMonGetDocuments:"];
$LSAMonFailure
]
];
LSAMonGetDocuments[___][xs_, context_Association] := $LSAMonFailure;
(**************************************************************)
(* General functions *)
(**************************************************************)
(*------------------------------------------------------------*)
(* Make document-term matrix *)
(*------------------------------------------------------------*)
Clear[LSAMonMakeDocumentTermMatrix];
SyntaxInformation[LSAMonMakeDocumentTermMatrix] = { "ArgumentsPattern" -> { _., _., OptionsPattern[] } };
Options[LSAMonMakeDocumentTermMatrix] = Join[ { "StemmingRules" -> {}, "StopWords" -> Automatic }, Options[DocumentTermSSparseMatrix] ];
LSAMonMakeDocumentTermMatrix[___][$LSAMonFailure] := $LSAMonFailure;
LSAMonMakeDocumentTermMatrix[xs_, context_Association] := LSAMonMakeDocumentTermMatrix[][xs, context];
LSAMonMakeDocumentTermMatrix[][xs_, context_Association] := LSAMonMakeDocumentTermMatrix[ {}, Automatic ][xs, context];
LSAMonMakeDocumentTermMatrix[ opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{ stemRules, stopWords },
stemRules = OptionValue[ LSAMonMakeDocumentTermMatrix, "StemmingRules" ];
If[ ! ( AssociationQ[stemRules] || DispatchQ[stemRules] || MatchQ[ stemRules, {_Rule...} ] || TrueQ[ stemRules === Automatic ] || BooleanQ[stemRules] ),
Echo[
"The value of the option \"StemmingRules\" is expected to be a list or rules, dispatch table, an association, or Automatic.",
"LSAMonMakeDocumentTermMatrix:"
];
Return[$LSAMonFailure]
];
stopWords = OptionValue[ LSAMonMakeDocumentTermMatrix, "StopWords" ];
If[ ! ( MatchQ[ stopWords, {_String...} ] || TrueQ[ stopWords === Automatic ] || TrueQ[ stopWords === None ] ),
Echo[
"The value of the option \"StopWords\" is expected to be a list or strings, Automatic, or None.",
"LSAMonMakeDocumentTermMatrix:"
];
Return[$LSAMonFailure]
];
LSAMonMakeDocumentTermMatrix[ stemRules, stopWords, DeleteCases[{opts}, ("StemmingRules" | "StopWords") -> _ ] ][xs, context]
];
LSAMonMakeDocumentTermMatrix[
stemRulesArg : ({ Rule[_String, _String] ... } | _Dispatch | _Association | Automatic | True | False),
stopWordsArg : {_String ...} | Automatic | None,
opts : OptionsPattern[] ][xs_, context_] :=
Block[{ stemRules = stemRulesArg, stopWords = stopWordsArg, docs, docTermMat, documentTermMatrixCreationOptions },
docs = Fold[ LSAMonBind, LSAMonUnit[xs, context], { LSAMonGetDocuments, LSAMonTakeValue } ];
If[ TrueQ[docs === $LSAMonFailure],
Echo["Ingest texts first.", "LSMonMakeDocumentTermMatrix:"];
Return[$LSAMonFailure]
];
If[ TrueQ[ stopWords === Automatic ],
stopWords = DictionaryLookup["*"];
stopWords = Complement[stopWords, DeleteStopwords[stopWords]];
];
If[ TrueQ[stemRules === False], stemRules = {} ];
If[ TrueQ[stemRules === True], stemRules = Automatic ];
documentTermMatrixCreationOptions = FilterRules[ {opts}, Options[DocumentTermSSparseMatrix]] ;
docTermMat = DocumentTermSSparseMatrix[ ToLowerCase /@ docs, {stemRules, stopWords}, None, documentTermMatrixCreationOptions ];
stemRules =
Which[
MatchQ[ stemRules, { Rule[_, _] .. } ],
Association[ stemRules ],
MatchQ[ stemRules, _Dispatch ],
Association[ Normal[stemRules] ],
True,
stemRules
];
LSAMonUnit[xs,
Join[context,
<| "documents" -> docs,
"documentTermMatrix" -> docTermMat,
"terms" -> ColumnNames[docTermMat],
"stopWords" -> stopWords,
"stemmingRules" -> stemRules,
"documentTermMatrixCreationOptions" -> documentTermMatrixCreationOptions
|>]]
];
LSAMonMakeDocumentTermMatrix[__][___] :=
Block[{},
Echo[
"The expected signature is one of LSAMonMakeDocumentTermMatrix[stemRules : ( { Rule[_String,_String] .. } | _Dispatch | _Association ), stopWords : { _String ... } | Automatic | None ] "
<> " or LSAMonMakeDocumentTermMatrix[OptionsPattern[]].",
"LSAMonMakeDocumentTermMatrix:"];
$LSAMonFailure
];
(*------------------------------------------------------------*)
(* Apply term weight function to matrix entries *)
(*------------------------------------------------------------*)
Clear[LSAMonApplyTermWeightFunctions];
SyntaxInformation[LSAMonApplyTermWeightFunctions] = { "ArgumentsPattern" -> { _., _., _., OptionsPattern[] } };
Options[LSAMonApplyTermWeightFunctions] = { "GlobalWeightFunction" -> "IDF", "LocalWeightFunction" -> "None", "NormalizerFunction" -> "Cosine" };
LSAMonApplyTermWeightFunctions[___][$LSAMonFailure] := $LSAMonFailure;
LSAMonApplyTermWeightFunctions[xs_, context_Association] := LSAMonApplyTermWeightFunctions[][xs, context];
LSAMonApplyTermWeightFunctions[ opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{ termFuncs, val },
termFuncs =
Table[
(
val = OptionValue[ LSAMonApplyTermWeightFunctions, funcName ];
If[ ! StringQ[val],
Echo[
"The value of the option \"" <> funcName <> "\" is expected to be a string.",
"LSAMonApplyTermWeightFunctions:"
];
Return[$LSAMonFailure]
];
val
),
{ funcName, { "GlobalWeightFunction", "LocalWeightFunction", "NormalizerFunction" } }
];
LSAMonApplyTermWeightFunctions[ Sequence @@ termFuncs ][xs, context]
];
LSAMonApplyTermWeightFunctions[globalWeightFunction_String, localWeightFunction_String, normalizerFunction_String][xs_, context_] :=
Block[{wDocTermMat, globalWeights, aSpec },
Which[
KeyExistsQ[context, "documentTermMatrix"] && SSparseMatrixQ[context["documentTermMatrix"]],
globalWeights =
AssociationThread[
ColumnNames[context["documentTermMatrix"]],
GlobalTermFunctionWeights[ SparseArray[context["documentTermMatrix"]], globalWeightFunction ]
];
wDocTermMat = WeightTermsOfSSparseMatrix[context["documentTermMatrix"], Values[globalWeights], localWeightFunction, normalizerFunction];
aSpec = AssociationThread[ {"globalWeightFunction", "localWeightFunction", "normalizerFunction"}, {globalWeightFunction, localWeightFunction, normalizerFunction}];
LSAMonUnit[xs, Join[context, <|"weightedDocumentTermMatrix" -> wDocTermMat, "globalWeights" -> globalWeights |>, aSpec]],
!KeyExistsQ[context, "documentTermMatrix"],
Echo["No document-term matrix.", "LSAMonApplyTermWeightFunctions:"];
$LSAMonFailure,
True,
Echo["The document-term matrix is not a SSparseMatrix object.", "LSAMonApplyTermWeightFunctions:"];
$LSAMonFailure
]
];
LSAMonApplyTermWeightFunctions[__][___] :=
Block[{},
Echo[
"The expected signature is one of LSAMonApplyTermWeightFunctions[globalWeightFunction_String, localWeightFunction_String, normalizerFunction_String]"
<> " or LSAMonApplyTermWeightFunctions[OptionsPattern[]].",
"LSAMonApplyTermWeightFunctions:"];
$LSAMonFailure
];
(*------------------------------------------------------------*)
(* Make document-term matrix *)
(*------------------------------------------------------------*)
Clear[LSAMonExtractTopics];
SyntaxInformation[LSAMonExtractTopics] = { "ArgumentsPattern" -> { _., OptionsPattern[] } };
Options[LSAMonExtractTopics] =
Join[
{ "NumberOfTopics" -> None, Method -> "NNMF", "MinNumberOfDocumentsPerTerm" -> 10, "NumberOfInitializingDocuments" -> 12,
"OrderBySignificance" -> True, "InitialTopics" -> None, Tolerance -> 10^-6 },
Options[NonNegativeMatrixFactorizationGlobal]
];
LSAMonExtractTopics[___][$LSAMonFailure] := $LSAMonFailure;
LSAMonExtractTopics[$LSAMonFailure] := $LSAMonFailure;
LSAMonExtractTopics[xs_, context_Association] := $LSAMonFailure;
(*LSAMonExtractTopics[nTopics_Integer, nMinDocumentsPerTerm_Integer, nInitializingDocuments_Integer, opts : OptionsPattern[]][xs_, context_] :=*)
(* LSAMonExtractTopics[ nTopics, Join[ { "MinNumberOfDocumentsPerTerm" -> nMinDocumentsPerTerm, "NumberOfInitializingDocuments" -> nInitializingDocuments }, {opts}] ][xs, context];*)
LSAMonExtractTopics[ opts : OptionsPattern[] ][xs_, context_] :=
Block[{nTopics},
nTopics = OptionValue[ LSAMonExtractTopics, "NumberOfTopics" ];
If[ ! IntegerQ[nTopics],
Echo[
"The value of the option \"NumberOfTopics\" is expected to be a integer.",
"LSAMonExtractTopics:"
];
Return[$LSAMonFailure]
];
LSAMonExtractTopics[ nTopics, opts ][xs, context]
];
LSAMonExtractTopics[ nTopics_Integer, opts : OptionsPattern[] ][xs_, context_] :=
Block[{method, nMinDocumentsPerTerm, nInitializingDocuments, orderBySignificanceQ, initialTopics,
docTermMat, documentsPerTerm, pos, W, H, M1, k, p, m, n, U, S, V,
nnmfOpts, terms, automaticTopicNames, topicsSFactors, initialTopicsIndexes, Wcols},
method = OptionValue[ LSAMonExtractTopics, Method ];
If[ StringQ[method], method = ToLowerCase[method]];
If[ TrueQ[ MemberQ[ {SingularValueDecomposition, ToLowerCase["SingularValueDecomposition"], ToLowerCase["SVD"] }, method ] ], method = "SVD" ];
If[ TrueQ[ MemberQ[ ToLowerCase[ { "NNMF", "NMF", "NonNegativeMatrixFactorization" } ], method ] ], method = "NNMF" ];
If[ TrueQ[ MemberQ[ ToLowerCase[ { "IndependentComponentAnalysis", "ICA" } ], method ] ], method = "ICA" ];
If[ !MemberQ[ {"SVD", "NNMF", "ICA"}, method ],
Echo["The value of the option Method is expected to be \"SVD\", \"NNMF\", or \"ICA\".", "LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
nMinDocumentsPerTerm = OptionValue[ LSAMonExtractTopics, "MinNumberOfDocumentsPerTerm" ];
If[ ! ( IntegerQ[ nMinDocumentsPerTerm ] && nMinDocumentsPerTerm >= 0 ),
Echo["The value of the option \"MinNumberOfDocumentsPerTerm\" is expected to be a non-negative integer.", "LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
nInitializingDocuments = OptionValue[ LSAMonExtractTopics, "NumberOfInitializingDocuments" ];
If[ ! ( IntegerQ[ nInitializingDocuments ] && nInitializingDocuments > 0 ),
Echo["The value of the option \"NumberOfInitializingDocuments\" is expected to be a positive integer.", "LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
orderBySignificanceQ = TrueQ[OptionValue[ LSAMonExtractTopics, "OrderBySignificance" ]];
initialTopics = OptionValue[ LSAMonExtractTopics, "InitialTopics" ];
If[ ! ( MatchQ[ initialTopics, { { _String ..} ..} ] || TrueQ[initialTopics === None] ),
Echo["The value of the option \"InitialTopics\" is expected to be a list of lists of strings or None.", "LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
(* No weighted document-term matrix. *)
If[ !KeyExistsQ[context, "weightedDocumentTermMatrix"],
Return[
Fold[
LSAMonBind,
LSAMonUnit[xs, context],
{
LSAMonApplyTermWeightFunctions[],
LSAMonExtractTopics[
nTopics,
Join[ { Method -> method, "MinNumberOfDocumentsPerTerm" -> nMinDocumentsPerTerm, "NumberOfInitializingDocuments" -> nInitializingDocuments }, {opts}]
]
}
]
]
];
If[ nMinDocumentsPerTerm > RowsCount[context["weightedDocumentTermMatrix"]],
Echo[
"The value of the option \"MinNumberOfDocumentsPerTerm\" is expected not to be greater than the number of rows of the weighted document-term matrix.",
"LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
(* Restrictions *)
docTermMat = Unitize[ SparseArray[ context["weightedDocumentTermMatrix"] ] ];
documentsPerTerm = Total /@ Transpose[docTermMat];
pos = Flatten[Position[documentsPerTerm, s_?NumberQ /; s >= nMinDocumentsPerTerm]];
If[ Length[pos] == 0,
Echo[
"The value of the option \"MinNumberOfDocumentsPerTerm\" produced an empty selection of terms (columns of the weighted document-term matrix.)",
"LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
M1 = SparseArray[ context["weightedDocumentTermMatrix"][[All, pos]] ];
(* Initial topics to lists of term indexes. *)
If[ ListQ[initialTopics],
initialTopicsIndexes = AssociationThread[ ColumnNames[context["weightedDocumentTermMatrix"]][[pos]], Range[Length[pos]]];
initialTopicsIndexes = Map[ Lookup[ initialTopicsIndexes, #, $Failed]&, initialTopics, {-1}];
If[ !FreeQ[initialTopicsIndexes, $Failed],
If[ Union[Flatten[initialTopicsIndexes]] == {$Failed},
Echo[
"None of the specified initial topics terms are column names in the restricted weighted document-term matrix.",
"LSAMonExtractTopics:"];
Return[$LSAMonFailure],
(*ELSE*)
Echo[
"Some of the specified initial topics terms are not column names in the restricted weighted document-term matrix.",
"LSAMonExtractTopics:"]
]
];
initialTopicsIndexes = DeleteCases[initialTopicsIndexes, $Failed, 2];
];
(* Factorization *)
Which[
(* Non-negative matrix factorization *)
method == "NNMF" && KeyExistsQ[context, "weightedDocumentTermMatrix"] && SSparseMatrixQ[context["weightedDocumentTermMatrix"]],
{k, p} = {nTopics, nInitializingDocuments};
{m, n} = Dimensions[M1];
M1 = Transpose[M1];
M1 = Map[Identity, M1];
H = ConstantArray[0, {k, n}];
W = Table[Total[RandomSample[M1, UpTo[p]]], {k}];
If[ ListQ[initialTopics],
Wcols = Map[ Total[M1[[#]], 1]&, initialTopicsIndexes];
Do[W[[i]] = Wcols[[i]], {i, 1, Length[Wcols]}]
];
Do[
W[[i]] = W[[i]] / Norm[W[[i]]];
, {i, 1, Length[W]}];
W = Transpose[W];
M1 = SparseArray[M1];
M1 = Transpose[M1];
W = SparseArray[W];
H = SparseArray[H];
nnmfOpts = FilterRules[ {opts}, Options[NonNegativeMatrixFactorizationGlobal] ];
If[ TrueQ[ ("MaxSteps" /. nnmfOpts) === Automatic ],
nnmfOpts = Prepend[ nnmfOpts, "MaxSteps" -> 12 ];
];
{W, H} = NonNegativeMatrixFactorizationGlobal[M1, W, H, Evaluate[ nnmfOpts ] ],
(* Singular Value Decomposition *)
method == "SVD" && KeyExistsQ[context, "weightedDocumentTermMatrix"] && SSparseMatrixQ[context["weightedDocumentTermMatrix"]],
{U, S, V} = SingularValueDecomposition[ M1, nTopics, DeleteCases[ FilterRules[ {opts}, Options[SingularValueDecomposition] ], Method -> _ ]];
(* Re-fit the result to monad's data interpretation. *)
W = SparseArray[U];
H = Transpose[V];
H = S . H,
!KeyExistsQ[context, "weightedDocumentTermMatrix"],
Echo["Cannot find a weighted document-term matrix.", "LSAMonExtractTopics:"];
Return[$LSAMonFailure],
(* Independent Component Analysis *)
method == "ICA" && KeyExistsQ[context, "weightedDocumentTermMatrix"] && SSparseMatrixQ[context["weightedDocumentTermMatrix"]],
{H, W} = IndependentComponentAnalysis[ Transpose[M1], nTopics, DeleteCases[ FilterRules[ {opts}, Options[IndependentComponentAnalysis] ], Method -> _ ]];
(* Re-fit the result to monad's data interpretation. *)
W = Transpose[SparseArray[W]];
H = Transpose[SparseArray[H]],
!KeyExistsQ[context, "weightedDocumentTermMatrix"],
Echo["Cannot find a weighted document-term matrix.", "LSAMonExtractTopics:"];
Return[$LSAMonFailure],
(* No matrix. *)
True,
Echo["The weighted document-term matrix is not a SSparseMatrix object.", "LSAMonExtractTopics:"];
Return[$LSAMonFailure]
];
If[ method != "SVD" && orderBySignificanceQ,
{W, H} = RightNormalizeMatrixProduct[ W, H ];
topicsSFactors = Sqrt[ Total[W * W] ];
W = W[[ All, Reverse[Ordering[topicsSFactors]] ]];
H = H[[ Reverse[Ordering[topicsSFactors]], All ]];
topicsSFactors = ReverseSort[topicsSFactors];
];
terms = ColumnNames[context["weightedDocumentTermMatrix"]];
automaticTopicNames =
Table[
StringJoin[Riffle[BasisVectorInterpretation[Normal@H[[ind]], 3, terms[[pos]]][[All, 2]], "-"]],
{ind, 1, Dimensions[W][[2]]}];
If[ ! DuplicateFreeQ[automaticTopicNames],
automaticTopicNames = MapIndexed[ #1 <> "-" <> ToString[#2]&, automaticTopicNames ];
];
W = ToSSparseMatrix[ SparseArray[W], "RowNames" -> RowNames[context["weightedDocumentTermMatrix"]], "ColumnNames" -> automaticTopicNames ];
H = ToSSparseMatrix[ SparseArray[H], "RowNames" -> automaticTopicNames, "ColumnNames" -> ColumnNames[context["weightedDocumentTermMatrix"]][[pos]] ];
LSAMonUnit[xs,
Join[context, <|
"W" -> W, "H" -> H, "topicColumnPositions" -> pos,
"automaticTopicNames" -> automaticTopicNames, "terms" -> terms,
"method" -> method |>]]
];
LSAMonExtractTopics[___][__] :=
Block[{},
Echo[
"The expected signature is LSAMonExtractTopics[ nTopics_Integer, opts___] .",
"LSAMonExtractTopics::"];
$LSAMonFailure
];
LSAMonTopicExtraction = LSAMonExtractTopics;
(*------------------------------------------------------------*)
(* Extract statistical thesaurus *)
(*------------------------------------------------------------*)
Clear[LSAMonExtractStatisticalThesaurus];
SyntaxInformation[LSAMonExtractStatisticalThesaurus] = { "ArgumentsPattern" -> { _., _., OptionsPattern[] } };
Options[LSAMonExtractStatisticalThesaurus] = { "Words" -> None, "NumberOfNearestNeighbors" -> 12 };
LSAMonExtractStatisticalThesaurus[___][$LSAMonFailure] := $LSAMonFailure;
LSAMonExtractStatisticalThesaurus[ opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{words, numberOfNNs},
words = OptionValue[ LSAMonExtractStatisticalThesaurus, "Words" ];
If[ ! MatchQ[ words, {_String..} ],
Echo[
"The value of the option \"Words\" is expected to be a list of strings.",
"LSAMonExtractStatisticalThesaurus:"
];
Return[$LSAMonFailure]
];
numberOfNNs = OptionValue[ LSAMonExtractStatisticalThesaurus, "NumberOfNearestNeighbors" ];
If[ ! MatchQ[ words, {_String..} ],
Echo[
"The value of the option \"Words\" is expected to be a list of strings.",
"LSAMonExtractStatisticalThesaurus:"
];
Return[$LSAMonFailure]
];
LSAMonExtractStatisticalThesaurus[ words, numberOfNNs ][xs, context]
];
LSAMonExtractStatisticalThesaurus[word_String, numberOfNNs_Integer][xs_, context_Association] :=
LSAMonExtractStatisticalThesaurus[{word}, numberOfNNs][xs, context];
LSAMonExtractStatisticalThesaurus[words : {_String ..}, numberOfNNs_Integer][xs_, context_Association] :=
Block[{W, H, HNF, thRes},
Which[
KeyExistsQ[context, "H"] && KeyExistsQ[context, "W"],
{W, H} = NormalizeMatrixProduct[ SparseArray[context["W"]], SparseArray[context["H"]] ];
HNF = Nearest[Range[Dimensions[H][[2]]], DistanceFunction -> (Norm[H[[All, #1]] - H[[All, #2]]] &)];
thRes =
Association[
Map[
# -> NearestWords[HNF, #, ColumnNames[context["H"]], {}, numberOfNNs] &,
Sort[words]]
];
LSAMonUnit[thRes, Join[context, <|"statisticalThesaurus" -> thRes|>]],
True,
Echo["No factorization of the document-term matrix is made.", "LSAMonExtractStatisticalThesaurus:"];
$LSAMonFailure
]
];
LSAMonExtractStatisticalThesaurus[___][__] :=
Block[{},
Echo[
"The expected signature is one of LSAMonExtractStatisticalThesaurus[words : {_String ..}, numberOfNNs_Integer] "
<> " or LSAMonExtractStatisticalThesaurus[OptionsPattern[]].",
"LSAMonExtractStatisticalThesaurus::"];
$LSAMonFailure
];
(*------------------------------------------------------------*)
(* Echo statistical thesaurus *)
(*------------------------------------------------------------*)
Clear[LSAMonEchoStatisticalThesaurusTable];
SyntaxInformation[LSAMonEchoStatisticalThesaurusTable] = { "ArgumentsPattern" -> { OptionsPattern[] } };
Options[LSAMonEchoStatisticalThesaurusTable] = Options[LSAMonExtractStatisticalThesaurus];
LSAMonEchoStatisticalThesaurusTable[___][$LSAMonFailure] := $LSAMonFailure;
LSAMonEchoStatisticalThesaurusTable[xs_, context_Association] := LSAMonEchoStatisticalThesaurusTable[][xs, context];
LSAMonEchoStatisticalThesaurusTable[ opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{words},
words = OptionValue[ LSAMonEchoStatisticalThesaurusTable, "Words" ];
Which[
!TrueQ[ words === None ],
Fold[ LSAMonBind, LSAMonUnit[xs, context], { LSAMonExtractStatisticalThesaurus[opts], LSAMonEchoStatisticalThesaurusTable } ],
TrueQ[ words === None ] && KeyExistsQ[context, "statisticalThesaurus"],
Echo[
Grid[
Prepend[
List @@@ Normal[ context["statisticalThesaurus"] ],
Style[#, Blue, FontFamily -> "Times"] & /@ {"term", "statistical thesaurus entries"}],
Dividers -> All, Alignment -> Left,
Spacings -> {Automatic, 0.75}],
"statistical thesaurus:"
];
LSAMonUnit[xs, context],
True ,
Echo["No statistical thesaurus is computed.", "LSAMonEchoStatisticalThesaurusTable:"];
$LSAMonFailure
]
];
LSAMonEchoStatisticalThesaurusTable[___][__] :=
Block[{},
Echo["No arguments are expected (options only.)", "LSAMonEchoStatisticalThesaurusTable:"];
$LSAMonFailure
];
Clear[LSAMonEchoStatisticalThesaurus];
LSAMonEchoStatisticalThesaurus = LSAMonEchoStatisticalThesaurusTable;
(*------------------------------------------------------------*)
(* Basis vector interpretation *)
(*------------------------------------------------------------*)
Clear[LSAMonInterpretBasisVector];
SyntaxInformation[LSAMonInterpretBasisVector] = { "ArgumentsPattern" -> { _., OptionsPattern[] } };
Options[LSAMonInterpretBasisVector] = { "TopicIndexes" -> All, "NumberOfTerms" -> 12 };
LSAMonInterpretBasisVector[___][$LSAMonFailure] := $LSAMonFailure;
LSAMonInterpretBasisVector[ opts : OptionsPattern[] ][xs_, context_Association] :=
Block[{topicIndexes},
topicIndexes = OptionValue[ LSAMonInterpretBasisVector, "TopicIndexes" ];
If[
!( IntegerQ[topicIndexes] && topicIndexes > 0 ||
VectorQ[ topicIndexes, IntegerQ ] && Min[topicIndexes] > 0 ||
TrueQ[topicIndexes === All] ),
Echo[
"The value of the option \"TopicIndexes\" is expected to be a positive integer, a list of positive integers, or All.",
"LSAMonInterpretBasisVector:"
];
Return[$LSAMonFailure]
];
LSAMonInterpretBasisVector[ topicIndexes, opts ][xs, context]
];
LSAMonInterpretBasisVector[vectorIndicesArg : ( All | _Integer | {_Integer..}), opts : OptionsPattern[] ][xs_, context_] :=
Block[{W, H, res, numberOfTerms, vectorIndices = vectorIndicesArg},
If[ !TrueQ[vectorIndices === All], vectorIndices = Flatten @ {vectorIndicesArg} ];
numberOfTerms = OptionValue[LSAMonInterpretBasisVector, "NumberOfTerms"];
If[ !( KeyExistsQ[context, "W"] && KeyExistsQ["H"] ),
Echo["Cannot find matrix factors.", "LSAMonInterpretBasisVector:"];
Return[$LSAMonFailure]
];
{W, H} = RightNormalizeMatrixProduct[ SparseArray[context["W"]], SparseArray[context["H"]] ];
res =
Map[
BasisVectorInterpretation[#, numberOfTerms, ColumnNames[context["H"]] ]&,
Normal @ H[[ vectorIndices ]]
];
If[ !MatchQ[res, {{{_?NumberQ, _String}..}..}], Return[$LSAMonFailure] ];
res = Map[ Association[ Rule @@@ (Reverse /@ #) ]&, res ];
res = AssociationThread[ RowNames[context["H"]][[ vectorIndices ]], res ];
LSAMonUnit[ res, context ]
];
LSAMonInterpretBasisVector[___][__] :=
Block[{},
Echo[
"The expected signature is one of LSAMonInterpretBasisVector[vectorIndices:(All|_Integer|{_Integer..}), opts___] "