ported examples from BLEPeripheral buttonLED and callbackLED

Author: hbisby

libraries/CurieBle/examples/ButtonLED/buttonLED.ino

@@ -0,0 +1,82 @@
+/*
+  Copyright (c) 2015 Intel Corporation. All rights reserved.
+
+  This library is free software; you can redistribute it and/or
+  modify it under the terms of the GNU Lesser General Public
+  License as published by the Free Software Foundation; either
+  version 2.1 of the License, or (at your option) any later version.
+
+  This library is distributed in the hope that it will be useful,
+  but WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+  Lesser General Public License for more details.
+
+  You should have received a copy of the GNU Lesser General Public
+  License along with this library; if not, write to the Free Software
+  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-
+  1301 USA
+*/
+
+
+#include <CurieBle.h>
+
+const int ledPin = 13; // set ledPin to on-board LED
+const int buttonPin = 4; // set buttonPin to digital pin 4
+
+BlePeripheral blePeripheral; // create peripheral instance
+BleService ledService("19b10010e8f2537e4f6cd104768a1214"); // create service
+
+
+// create switch characteristic and allow remote device to read and write
+BleCharCharacteristic switchCharacteristic("19b10011e8f2537e4f6cd104768a1214", BleRead | BleWrite);
+// create button characteristic and allow remote device to get notifications
+BleCharCharacteristic buttonCharacteristic("19b10012e8f2537e4f6cd104768a1214", BleRead | BleNotify); // allows remote device to get notifications
+
+void setup() {
+  Serial.begin(9600);
+  pinMode(ledPin, OUTPUT); // use the LED on pin 13 as an output
+  pinMode(buttonPin, INPUT); // use button pin 4 as an input
+
+  // set a name for the BLE peripheral. Max length is 20 characters:
+  blePeripheral.setLocalName("Curie LED_Switch Sketch");
+  // set the UUID for the service this peripheral advertises:
+  blePeripheral.setAdvertisedServiceUuid(ledService.uuid());
+
+  // add service and characteristics
+  blePeripheral.addAttribute(ledService);
+  blePeripheral.addAttribute(switchCharacteristic);
+  blePeripheral.addAttribute(buttonCharacteristic);
+
+  // advertise the service
+  blePeripheral.begin();
+
+  Serial.println("Bluetooth device active, waiting for connections...");
+}
+
+void loop() {
+  // poll peripheral
+  blePeripheral.poll();
+
+  // read the current button pin state
+  char buttonValue = digitalRead(buttonPin);
+
+  // has the value changed since the last read
+  boolean buttonChanged = (buttonCharacteristic.value() != buttonValue);
+
+  if (buttonChanged) {
+    // button state changed, update characteristics
+    switchCharacteristic.setValue(buttonValue);
+    buttonCharacteristic.setValue(buttonValue);
+  }
+
+  if (switchCharacteristic.written() || buttonChanged) {
+    // update LED, either central has written to characteristic or button state has changed
+    if (switchCharacteristic.value()) {
+      Serial.println("LED on");
+      digitalWrite(ledPin, HIGH);
+    } else {
+      Serial.println("LED off");
+      digitalWrite(ledPin, LOW);
+    }
+  }
+}

libraries/CurieBle/examples/CallbackLED/CallbackLED.ino

@@ -0,0 +1,89 @@
+/*
+  Copyright (c) 2015 Intel Corporation. All rights reserved.
+
+  This library is free software; you can redistribute it and/or
+  modify it under the terms of the GNU Lesser General Public
+  License as published by the Free Software Foundation; either
+  version 2.1 of the License, or (at your option) any later version.
+
+  This library is distributed in the hope that it will be useful,
+  but WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+  Lesser General Public License for more details.
+
+  You should have received a copy of the GNU Lesser General Public
+  License along with this library; if not, write to the Free Software
+  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-
+  1301 USA
+*/
+
+
+#include <CurieBle.h>
+
+const int ledPin = 13; // set ledPin to use on-board LED
+BlePeripheral blePeripheral; // create peripheral instance
+
+BleService ledService("19b10000e8f2537e4f6cd104768a1214"); // create service
+
+// create switch characteristic and allow remote device to read and write
+BleCharCharacteristic switchChar("0x2015", BleRead | BleWrite);
+
+void setup() {
+  Serial.begin(9600);
+
+  pinMode(ledPin, OUTPUT); // use the LED on pin 13 as an output
+
+  // set a name for the local peripheral
+  blePeripheral.setLocalName("Curie LED Sketch");
+  // set the UUID for the service this peripheral advertises
+  blePeripheral.setAdvertisedServiceUuid(ledService.uuid());
+
+  // add service and characteristic
+  blePeripheral.addAttribute(ledService);
+  blePeripheral.addAttribute(switchChar);
+
+  // assign event handlers for connected, disconnected to peripheral
+  blePeripheral.setEventHandler(BleConnected, blePeripheralConnectHandler);
+  blePeripheral.setEventHandler(BleDisconnected, blePeripheralDisconnectHandler);
+
+  // assign event handlers for characteristic
+  switchChar.setEventHandler(BleWritten, switchCharacteristicWritten);
+
+
+  // advertise the service
+  blePeripheral.begin();
+
+  Serial.println(("Bluetooth device active, waiting for connections..."));
+}
+
+
+
+void loop() {
+  // poll peripheral
+  blePeripheral.poll();
+}
+
+void blePeripheralConnectHandler(BleCentral& central) {
+  // central connected event handler
+  Serial.print("Connected event, central: ");
+  Serial.println(central.address());
+}
+
+void blePeripheralDisconnectHandler(BleCentral& central) {
+  // central disconnected event handler
+  Serial.print("Disconnected event, central: ");
+  Serial.println(central.address());
+}
+
+void switchCharacteristicWritten(BleCentral& central, BleCharacteristic& characteristic) {
+  // central wrote new value to characteristic, update LED
+  Serial.print("Characteristic event, writen: ");
+
+  if (switchChar.value()) {
+    Serial.println("LED on");
+    digitalWrite(ledPin, HIGH);
+  } else {
+    Serial.println("LED off");
+    digitalWrite(ledPin, LOW);
+  }
+}